Office: WECHSELN in SUMMEWENNS

Hallo,

leider spuckt mir Excel bei meiner Formel einen allgemeinen Fehler aus, mit welchem ich nichts anfangen kann und ich absolut keinen Ansatz habe wie ich ihn löse.

Die Formel lautet:

=+SUMMEWENNS(--WECHSELN(INDIREKT("'"&A85&"'!G1:G5000");" € ";"");INDIREKT("'"&A85&"'!F1:F5000");"CLEARING*")



Das --WECHSELN(INDIREKT("'"&A85&"'!G1:G5000") allein funktioniert und =+SUMMEWENNS(INDIREKT("'"&A85&"'!G1:G5000");INDIREKT("'"&A85&"'!F1:F5000");"CLEARING*") liefert leider nur "0" da die Daten ein Sonderzeichen enthalten und ausgefiltert werden müssten. Das habe ich bisher mit einer Hilfsspalte gemacht, möchte dies aber in Zukunft vermeiden.

Ich hoffe ihr könnt mir helfen.

 

Hola,
keine Ahnung was du genau vorhast. Lade eine Exceldatei hoch und zeig mal, was gewechselt werden soll.
Gruß,
steve1da

 

Hallo Steve, anbei eine Beispieltabelle wie es aktuell noch gelöst ist.

 

Hallo Szen,

mit der Funktion SUCHEN und ERSETZEN kannst Du in der Spalte G das nach dem Zeichen 0160 suchen und dies durch "" (nichts) ersetzen.

 

Hi,

bei neuem Excel:

Code:

=SUMME(FILTER(--WECHSELN(INDIREKT("'"&A1&"'!G1:G5000");" €"&ZEICHEN(160);"");INDIREKT("'"&A1&"'!F1:F5000")="Dienstleistung1"))

bei älterem Excel:

Code:

=SUMME(WENN(INDIREKT("'"&A1&"'!F1:F5000")="Dienstleistung1";--WECHSELN(INDIREKT("'"&A1&"'!G1:G5000");" €"&ZEICHEN(160);"")))

Achtung, Matrixformel! Bei älterem Excel mit Strg-Shift-Enter abschließen.

 

Vielen Dank erstmal, das funktioniert fast so wie ich es möchte. Wenn ich allerdings Nach "*Dienstleistung1*" suche, da das Vorkommen des Wortes innerhalb der Zelle geprüft werden soll, bekomme ich einen #KALK - Fehler.

 

SUMME|ZÄHLEN|MITTELWERT|MAX|MIN|WENN|S erlauben nur Bereichsangaben, keine Bereichsmanipulationen, also

A:A ok
A1:A99 ok
A1:INDEX(A:A;X1) ok
A1:A99&B1:B99 NEIN
WECHSELN(A1:A99;"tot";"lebendig") NEIN

 

Hi,

dann brauchst du so etwas:

Code:

=SUMME(FILTER(--WECHSELN(INDIREKT("'"&A1&"'!G1:G50000");" € ";"");NICHT(ISTFEHLER(SUCHEN("dienstleistung1";INDIREKT("'"&A1&"'!F1:F50000"))))))

Analog dann beim alten Excel die Bedingung in WENN(Bedingung;Formel) anpassen.

 

Funktioniert leider auch nicht wenn ich

Code:

=SUMME(FILTER(--WECHSELN(INDIREKT("'"&A1&"'!G1:G5000");" € ";"");NICHT(ISTFEHLER(SUCHEN("AKKUTAUSCH";INDIREKT("'"&A1&"'!F1:F5000"))))))

verwende. Gibt #WERT aus.

 

Nicht eher sowas am Ende?
=SUMME(FILTER(--WECHSELN(INDIREKT("'"&A1&"'!G1:G5000");" €"&ZEICHEN(160);"");ISTZAHL(SUCHEN("dienstleistung1";INDIREKT("'"&A1&"'!F1:F5000")))))

 

Hi,

sorry, statt

Code:

" € "

musst du natürlich

Code:

" €"&ZEICHEN(160)

verwenden. und ISTZAHL() statt NICHT(ISTFEHLER()) ist natürlich auch schlauer.

 

Code:

=SUMME(FILTER(--WECHSELN(INDIREKT("'"&A1&"'!G1:G5000");" €"&ZEICHEN(160);"");ISTZAHL(SUCHEN("*Dienstleistung1*";INDIREKT("'"&A1&"'!F1:F5000")))))

funktioniert. Nur wenn ich jetzt mehrere Suchbegriffe habe, wo die Zahlen zusammengefasst werden sollen? also *Dienstleistung1*+*Dienstleistung2*+*Dienstleistung3*.

Habe es mit

Code:

=SUMME(FILTER(--WECHSELN(INDIREKT("'"&A1&"'!G1:G5000");" €"&ZEICHEN(160);"");ISTZAHL(SUCHEN("*Dienstleistung1*";INDIREKT("'"&A1&"'!F1:F5000")))))+SUMME(FILTER(--WECHSELN(INDIREKT("'"&A1&"'!G1:G5000");" €"&ZEICHEN(160);"");ISTZAHL(SUCHEN("*Dienstleistung2*";INDIREKT("'"&A1&"'!F1:F5000")))))

probiert aber da kommt wieder #KALK!.

Auch

Code:

=SUMME(FILTER(--WECHSELN(INDIREKT("'"&A1&"'!G1:G5000");" €"&ZEICHEN(160);"");ISTZAHL(SUCHEN({"*Dienstleistung1*";"*Dienstleistung2*"};";INDIREKT("'"&A1&"'!F1:F5000")))))

geht nicht.

 

Warum kommen solche Infos nicht direkt am Anfang? Ich warte dann erst mal, was noch so als Anforderung dazu kommt.

 

Entschuldige, mit summewenns ging es halt ohne Probleme mit dem +SUMMEWENNS…deshalb ging ich davon aus das es auch mit SUMME geht.

 

Hi,

=SUMME(FILTER(--WECHSELN(INDIREKT("'"&A1&"'!G1:G50000");" €"&ZEICHEN(160);"");ISTZAHL(SUCHEN("dienstleistung1";INDIREKT("'"&A1&"'!F1:F50000")))+ISTZAHL(SUCHEN("dienstleistung2";INDIREKT("'"&A1&"'!F1:F50000")))))

Und bei SUCHEN solltest du auf den * verzichten!

EDIT:
Wäre es statt einer solchen Monsterformel nicht einfacher den Vorschlag von neopa_C zu nutzen und eine vernünftige Ausgangsbasis zu schaffen? Dann kannst du die Standard-Funktionalitäten (Autofilter, Pivot etc.) von Excel nutzen