Office: (Office 365) Summewenns mit mehreren Bedingungen, Ausschluessen

Hallo,

ich müsste aus beigefügter Datei, normalerweise, ca. 40000 Zeilen, eine Summe mit folgenden Bedingungen erstellen, bzw. habe sie in j8 eingefügt. Leider funktioniert sie so nicht.

Die Bedingungen wären wie folgt:
Spalte A: Summe,
Spalte D, alles außer Konto 93910
Spalte E: nur 3 u. 5
Spalte F: alles außer Steuerschluessel 0
Spalte G: Alles außer GM und leer

In Spalte D kommen Leerzeichen mit raus. Das habe ich versucht mit abzudecken. Genauso in Spalte G.
Bei Summenprodukt ging es nicht, dass Konto in Spalte D auszuklammern, =SUMPRODUCT('Daten'!G1:G400000*('Daten'!J1:J400000<>93910&"*"))

Kann mir hier jemand weiterhelfen wo der Fehler liegt? Müsste ich mehrere Summewenns-Formeln nehmen?
Viele Grüsse
Matthias

 

Hola,
der Fehler ist, dass bei Summewenns() alles UND Bedingungen sind und somit zB in Spalte E 3 UND 5 gleichzeitig (aber Einzeln) in den Zellen stehen muss. Und das ist nicht möglich. Daher mit Summenprodukt.
=SUMMENPRODUKT((D5:D1000<>"93910")*((E5:E1000=3)+(E5:E1000=5))*(F5:F1000<>0)*((G5:G1000<>"gm")+(G5:G1000<>""))*(A5:A1000))
Gruß,
steve1da

 

Hi,

in 365 ginge das:

=SUMME(INDEX(FILTER(A4:H880;(D4:D880<>"93910")*((E4:E880=3)+(E4:E880=5))*(F4:F880<>0)*((G4:G880<>"GM")+(G4:G880<>" ")););;1))

 

Danke vielmals, funktioniert, wenn auch die Summe noch nicht ganz mit der Pivot uebereinstimmt, muss nochmal schauen, ob ich was uebersehen habe. Versuche eine Differenz zu finden.

 

Hallo,

überall in Deiner Tabelle sind Leerzeichen hinter Zahlen u. Texten. Entferne die (suchen/Ersetzen) und dann funktioniert die Formel:

=SUMME(INDEX(FILTER(A4:H880;(D4:D880<>93910)*((E4:E880=3)+(E4:E880=5))*(F4:F880<>0)*(G4:G880<>"GM"););;1))

=SUMMENPRODUKT((D5:D1000<>"93910")*((E5:E1000=3)+(E5:E1000=5)>0)*(F5:F1000<>0)*(G5:G1000<>"gm")*(A5:A1000))

 

Hallo,

um den vielen enthaltenen Leerzeichen aus dem Weg zu gehen, müsste folgende Formel funktionieren:
=SUMMENPRODUKT((WERT(Table32[Konto])<>93910)* ((Table32[atp]=3)+(Table32[atp]=5))* (Table32[Steuerschluessel]<>0)* ((GLÄTTEN(Table32[Land])="GM")+(GLÄTTEN(Table32[Land])="")=0)* (Table32[Recorded amount]))

oder aber falls du im Besitz der neuesten Version von Excel365-Insider bist:
=LET(kto;REGEXTEST(Table32[Konto];"^93910"); atp;REGEXTEST(Table32[atp]; "3|5"); land;REGEXTEST(Table32[Land]; "^(GM|\s)"); SUMMENPRODUKT(NICHT(kto) * atp * (Table32[Steuerschluessel] <> 0) * NICHT(land) * Table32[Recorded amount]))

 

Hi,

nur zur "Abrundung": Das geht auch mit SUMMEWENNS:

=SUMME(SUMMEWENNS(A:A;D:D;"<>93910";E:E;{3.5};F:F;"<>0";G:G;"<>GM";G:G;"<>"))

Freilich solltest Du - wie von Edgar schon geschrieben - mal alle Leerzeichen aus den Einträgen entfernen.

 

Hallo Edgar,
danke, werde die Formel versuchen. Ja, ich weiss wegen der Leerzeichen, die kommen im Report mit raus. Ok hab's einfach nur Leerzeichen ohne Anfuehrungszeichen hat funktioniert. Werde die Formeln ausprobieren.