Office: Access 2010 - Vba Verschachtelte If Anweisung

Guten Morgen,

ich mal wieder mit einem Problem

Es gibt ein Access Makro, das nicht mehr funktioniert und ich versuche rauszufinden warum. Explizit geht es um diese If Anweisung.

Code:

 If bImport = False Then
        MsgBox "Es wurde ein neuer Datenbestand gefunden. Die neuen Daten werden importiert. Dieser Vorgang kann einige Zeit dauern." & vbCrLf & "Aktueller Stand wird in der Statuszeile angezeigt.", vbInformation, "Info"
        
        If getFileTime(getFilePath("txt_seisslager")) <> Nz(DLookup("bdTime", "tblBasisdaten", "bdKey='txt_seisslager'"), DateSerial(1900, 1, 1)) Then Call importSeisslagerTXT
        If getFileTime(getFilePath("xls_gf")) <> Nz(DLookup("bdTime", "tblBasisdaten", "bdKey='xls_gf'"), DateSerial(1900, 1, 1)) Then Call modImportDaten.importWerberegelnGF
        If getFileTime(getFilePath("xls_nf")) <> Nz(DLookup("bdTime", "tblBasisdaten", "bdKey='xls_nf'"), DateSerial(1900, 1, 1)) Then Call modImportDaten.importWerberegelnNF
        Me.Requery
        MsgBox "Import wurde abgeschlossen.", vbInformation, "Info"
    End If

Mein Problem dabei ist, das er das Call.. im Then teil nicht ausführt. Jetzt wollte ich ein Else einbauen, um zusehen ob die Bedinung von den If Teilen überhaupt war ist. Und genau da hänge ich. In den oberen Teil springt er rein, aber bei den If teilen stimmt anscheinend die Bedinung nicht.

Ich wollte jetzt ein Else zu jeder Bedinung einbauen, aber er bezieht dann das Else glaube ich auf den äußeren IF teil, weil er da nicht reinspringt.
Oder wie kann ich sonst rausfinden, ob meine Bedingungen wahr sind?

Hoffentlich ist das jetzt einigermaßen verständlich

Dankeschön!

 

Moinsens!

Wenn Du ein

Code:

IF {bedingung} THEN {anweisung}

in einer Zeile hälst, brauchst Du kein END IF, kannst es am Ende aber trotzdem auch mit ELSE erweitern:

Code:

IF {bedingung} THEN {anweisung} ELSE {anweisung}

Ich würde aber immer empfehlen, alleine schon aus Gründen der Übersichtlichkeit, aber auch aus Gründen der Erweiterbarkeit, IF .. THEN auf mehrere Zeile aufzutrennen, auch wenn nur eine Anweisung in den Blöcken ist:

Code:

IF {bedingung} THEN
    {anweisungsblock}
  ELSE
    {anweisungsblock}
END IF

Dein Code wäre dann so in der Art möglich:

Code:

    If bImport = False Then
    
        MsgBox "Es wurde ein neuer Datenbestand gefunden. Die neuen Daten werden importiert. Dieser Vorgang kann einige Zeit dauern." & vbCrLf & "Aktueller Stand wird in der Statuszeile angezeigt.", vbInformation, "Info"
        
        If getFileTime(getFilePath("txt_seisslager")) <> Nz(DLookup("bdTime", "tblBasisdaten", "bdKey='txt_seisslager'"), DateSerial(1900, 1, 1)) Then
            Call importSeisslagerTXT
          Else
            MsgBox "1 nicht"
        End If
        If getFileTime(getFilePath("xls_gf")) <> Nz(DLookup("bdTime", "tblBasisdaten", "bdKey='xls_gf'"), DateSerial(1900, 1, 1)) Then
            Call modImportDaten.importWerberegelnGF
          Else
            MsgBox "2 nicht"
        End If
        If getFileTime(getFilePath("xls_nf")) <> Nz(DLookup("bdTime", "tblBasisdaten", "bdKey='xls_nf'"), DateSerial(1900, 1, 1)) Then
            Call modImportDaten.importWerberegelnNF
          Else
            MsgBox "3 nicht"
        End If
        
        Me.Requery
        MsgBox "Import wurde abgeschlossen.", vbInformation, "Info"
    
    End If

Gruß, Michael

 

Vielen Dank, das hat mir sehr weitergeholfen :D

jetzt weiß ich wenigstens schonmal, das er nicht in den Then teil geht, sonder zum Else und kann mit Lösungfinden weitermachen.