Office: Autofill bis zur letzten Zeile

mthorsten · 21. Februar 2015

Hallo,
ich bin auf der Suche nach einer Lösung, um das unten stehende VBA Skript so anzupassen, dass die Formel bis zur letzten Zeile der Tabelle ausgeführt wird, was nicht unbedingt B164 sein soll, wie es im Skript steht. Der Wert B164 sollte variabel sein.

Wie löse ich das am Besten? Ich habe schon eingies ausprobiert, leider ohne Erfolg. Danke im Voraus! *Smilie

Code:

Sub Doppelte_Artnr()
'
' Doppelte_Artnr Makro
'

'
Sheets("Rohdaten").Select
Range("A1").Select
Range(Selection, Selection.End(xlToRight)).Select
Selection.Font.Bold = True
Selection.AutoFilter
Columns("B:B").Select
Selection.Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove
Range("B2").Select
ActiveCell.FormulaR1C1 = "=IF(OR(R[-1]C[-1]=RC[-1],RC[-1]=R[1]C[-1]),1,0)"
Range("B2").Select
Selection.AutoFill Destination:=Range("B2:B164")
Range("B2:B164").Select
Range("B1").Select
ActiveCell.FormulaR1C1 = "Abgleich Art-Nr."
Columns("B:B").Select
With Selection.Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.Color = 65535
.TintAndShade = 0
.PatternTintAndShade = 0
End With
Columns("B:B").EntireColumn.AutoFit
Range("B4").Select
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

:)

Hajo_Zi · 23. Februar 2015

Letzte Zelladresse mit und ohne VBA
(unabhängig von der Spalte) Zeilennummer ermitteln
Die allerletzte benutzte Zeile, unabhängig von der Spalte liefert:
MsgBox Sheets(1).UsedRange.SpecialCells(xlCellTypeLastCell).Row

petra_73 · 23. Februar 2015

Wenn Du eine ReferenzSpalte hast und die letzte Zeile für diese Spalte ermitteln willst, kannst du dies z.B. auch so machen:

letzteZeile = Cells(Rows.Count, "A").End(xlUp).Row

Hier wird die letzte Zeile in Spalte A ermittelt.

Hajo_Zi · 23. Februar 2015

aber nur falls die letzte Zeile in der Spalte nicht belegt.

petra_73 · 23. Februar 2015

Meinst Du Zeile 1.048.576?

Hajo_Zi · 23. Februar 2015

ja, das ist bei mir die letzte Zeile in der Spalte.

mthorsten · 23. Februar 2015

Hallo,
vielen Dank schon mal für die Hilfe, könntet ihr mir noch sagen, wie ich eine dieser Lösungen in meinen bestehenden VBA Code einbauen kann?

Sheets(2).UsedRange.SpecialCells(xlCellTypeLastCell).Row liefert mit den gewünschten Wert, ich weiß nur nicht, wie ich ihn in meinen Code einbauen. Vielen Dank!

Hajo_Zi · 23. Februar 2015

Range("B2:B" & LoZeile).Select

Select, Activate usw. ist in VBA zu 99,9% nicht notwendig.
Der Cursor ist kein Hund der überall rumgeführt werden muss.
Hinweise zu select usw. Online-Excel.de
Gruß Hajo

mücke · 23. Februar 2015

Moin mthorsten,

da Du dich in der Formel auf Werte der Spalte A beziehst, gehe ich davon aus, dass hier auch der "letzte" Wert steht.

Anbei mal eine kleine Anpassung ohne Select. Auf "Select" kann man zu 99% verzichten.
Code:

Option Explicit

Sub beispiel()

Dim loletzte As Long

With Worksheets("Rohdaten")

loletzte = .Cells(Rows.Count, 1).End(xlUp).Row

.Columns("B").EntireColumn.Insert
.Range("B1").Value = "Abgleich Art-Nr."
.Range("B2:B" & loletzte).FormulaLocal = "=WENN(ODER(A1=A2;A2=A3);1;0)"

.Range("A1").Select
Selection.AutoFilter
.Range(Selection, Selection.End(xlToRight)).Font.Bold = True

.Columns("A:C").EntireColumn.AutoFit

With Range("B1:B" & loletzte).Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.Color = 65535
.TintAndShade = 0
.PatternTintAndShade = 0
End With

End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

mthorsten · 23. Februar 2015

Vielen Dank an alle Unterstützer, jetzt funktioniert es wie gewünscht!

Das mit dem "Select" versuche ich weitestgehend zu meiden, ich habe bisher allerdings noch nicht viel Erfahrung mit VBA gemacht, weshalb ich die Makros einfach aufgezeichnet habe. Ich werde euren Tipp aber beherzigen.

Danke nochmal! *Smilie

Office: Autofill bis zur letzten Zeile

Autofill bis zur letzten Zeile

Autofill bis zur letzten Zeile

Autofill bis zur letzten Zeile

Autofill bis zur letzten Zeile

Autofill bis zur letzten Zeile - Similar Threads - Autofill Zeile

Formel auf Spalte übertragen

Schleifen zählen und Autofill

Feldinhalte automatisch an anderer Stelle auffüllen

Variable Zelleninformationen in anderen Tabellenblätter einfügenlassen (Autofill?)

Makro zu AutoFill

Excel autofill

Zellenautofill Makro stürzt ab, nach neuer Zeile einfügen