Office: Automatisch Zeilen kopieren

Hallo Zusammen,

ich bin dringend auf der Suche nach einer Möglichkeit, wie ich im Excel Zeilen automatisch kopieren kann. Und zwar unter best. Bedingungen.
Ich kenne leider nur die "Standard-Excel-Funktionen" und somit bin ich nicht in der Lage Makros zu programmieren bzw. welche die man im Forum findet auf meinen Fall anzupassen :cry:

Ich hoffe ihr könnt mir schnell helfen, da ich es dringend benötige.

So nun zur Aufgabenstellung :-)
Ich habe zehn einzelne Excel-Dateien (sagen wir Test1.xls, Test2.xls,Test3.xls,...,Test10.xls)
Ich möchte nun (alle) beschriebenen Zeilen aus den einzelnen Dateien in eine Excel-Tabelle kopieren (mit den Namen Überblick.xls)
-->Das Programm soll erst aus der Datei Test1.xls (alle) befüllten Zeilen in die Datei Überblick.xls kopieren, dann in die Datei Test2.xls und dort (alle) befüllten Zeilen in den Überblick.ls kopieren und zwar in die nächst freie Zeile. Damit zum Schluss alle Zeilen aus allen Dateien in einer Datei untereinander stehen.
Man muss dazu sagen, dass in jeder Datei in der erste Zeile die gleichen Überschriften stehen somit, muss diese nicht kopiert werden und im Überblick dürfen die Zeilen erst ab der 2. Zeile eingefügt werden.

(Info: 1. Zeile nicht kopieren, da Überschrifszeile.
Die Anzahl an befüllten Zeilen ist je Datei unterschiedlich. Jedoch soll er nur den Bereich von Zeile 2 bis zur nächsten freien Zeile kopieren. Wichtig da ab ca. Zeile 20 andere Dinge ausgefüllt werden, die mich nicht interessieren. Aber wie gesagt zwischen dem notwendigen und nicht notwenigen Bereich ist immer eine Leerzeile.)

Ich hoffe das war jetzt verständlich und ihr könnt mir schnell eine Lösung vorschlagen. :-)

Vielen herzlichen Dank (für die Rettung).

 

Hallo,

Dir ist schon bewusst, dass Du ohne ein gewisses Mindestmaß an VBA nicht auskommen wirst, noch dazu, da Du offenbar keine vollständige Beschreibung Deines Problems angegeben hast:
1) Wie heißen die Arbeitsblätter in Deinen Excel-Dateien? Im Makro habe ich dafür das 1. Arbeitsblatt angenommen.
2) Wie heißen die Excel-Dateien wirklich? Test1.xls... werden sie ja nicht heißen. Im Makro habe ich Deine Namen "Test1.xls",... angenommen.
3) In welchem Verzeichnis stehen die Dateien? Im Makro habe ich den Pfad "I:\EXCEL\Forum\" angenommen.

Das Makro lautet (ich habe jede Menge Kommentar eingefügt, um die Makrologik möglichst verständlich darzustellen):

Code:

Public Sub Kopieren_in_Sammelblatt()
' Variablen für das Sammelblatt:
  Dim WbSa As Workbook, WsSa As Worksheet, ZeilenSa&
' Variablen für die 10 Arbeitsblätter/Dateien:
  Dim WbI As Workbook, WsI As Worksheet, RgI As Range
  Dim ZeilenI&, I%, DateiI$, Pfad$
  
' Verwendet in der aktiven Arbeitsmappe das 1. Arbeitsblatt,
' um dort ab Zeile 2 die Werte der anderen Blätter einzufügen
  Set WbSa = ActiveWorkbook
  Set WsSa = WbSa.Worksheets(1)
  ZeilenSa& = 2
  
' Pfad$ enthält den Dateipfad auf das Verzeichnis, in dem sich
' die 10 Dateien "Test1.xls" ... "Test10.xls" befinden
' (muss unbedingt an Deine Verhältnisse angepasst werden!!)
  Pfad$ = "I:\EXCEL\Forum\"
  
' Führe das Folgende mit I=1, I=2 bis I=10 durch:
  For I% = 1 To 10
    'Ermittle den Dateinamen: "Test1.xls","Test2.xls", ..., "Test10.xls",
    'je nachdem welchen Wert I besitzt:
    DateiI$ = "Test" & I% & ".xls"
    'Öffne die Datei DateiI$ als neue Arbeitsmappe WbI
    Set WbI = Application.Workbooks.Open(Pfad$ & DateiI$)
    'Nimm dort das 1. Arbeitsblatt (WsI) her
    Set WsI = WbI.Worksheets(1)
    'und ermittle ab Zelle A1 denjenigen rechteckigen Zellbereich, der Werte enthält.
    'Die 1. Leerzeile und die 1. Leerspalte begrenzen diesen Bereich:
    Set RgI = WsI.Cells(1, 1).CurrentRegion
    'Ermittle die Zeilenanzahl dieses Bereiches, jedoch ohne die eine Kopfzeile:
    ZeilenI& = RgI.Rows.Count - 1
    'Der Bereich RgI soll schließlich den ursprünglichen Bereich, aber ohne Kopfzeile enthalten:
    Set RgI = RgI.Offset(1, 0).Resize(ZeilenI&)
    'Kopiere den Bereich RgI in das Sammelblatt WsSa und zwar ab Zeile ZeilenSa&
    RgI.Copy Destination:=WsSa.Cells(ZeilenSa&, 1)
    'Schließe schließlich die Arbeitsmappe WbI wieder:
    WbI.Close SaveChanges:=False
    'und erhöhe fürs Sammelblatt den Zeilenzähler ZeilenSa& um die eingefügte Zeilenanzahl:
    ZeilenSa& = ZeilenSa& + ZeilenI&
    'Erhöhe I um 1 und fahre mit nächstem Dateinamen fort:
  Next I%
  
End Sub

Zur Installation des Makros:
1) Obigen weißen Bereich mit der Maus markieren und die Tastenkombination Strg+C drücken, um das Makro in die Zwischenablage einzufügen.
2) Daraufhin in das Excel-Arbeitsblatt, in dem die gesammelten Texte stehen sollen, wechseln
3) Die Tastenkombination Alt+F11 drücken, um in den VBA-Editor zu gelangen.
4) Im VBA-Editor gibt es ein Menü. Dort "Einfügen > Modul" anklicken, sodass sich ein großes Programmfenster öffnet (=allgem. Codemodul), in dem der Texteingabe-Cursor blinkt.
5) Dort die Tastenkombination Strg+V drücken, um das Makro aus der Zwischenablage hier im Codemodul einzufügen.
6) Du musst jetzt das Makro an Deine Verhältnisse anpassen (Punkte 6a, 6b, 6c):
6a) Insbesondere den Pfad zum Verzeichnis, in dem sich Deine Dateien befinden (in der Makrovorgabe: "I:\EXCEL\Forum\")
6b) Wahrscheinlich auch die Stelle, in der die 10 Dateinamen erzeugt werden (in der Makrovorgabe: "Test1.xls", "Test2.xls",..., "Test10.xls")
6c) und möglicherweise auch das Arbeitsblatt in den Dateien (mein Makro nimmt immer das 1. Arbeitsblatt).
7) Daraufhin drückst Du wieder die Tastenkombination Alt+F11, um zurück ins ursprüngliche Excel-Arbeitsblatt zu wechseln. Damit ist das Makro installiert.

Anwendung des Makros:
Am schnellsten kannst Du das Makro anwenden, indem Du die Tastenkombination Alt+F8 drückst und anschließend die EINGABE-Taste.