Office: Bestimmte Zeilen auslesen

Hi,
Ich habe eine Tabelle mit mehreren Zeilen mit verschiedenen Werten. Ich möchte gerne alle Zeilen die den Wert "1 oder 2 oder 3 etc" in Spalte A enthalten in ein neues Tabellenblatt kopieren.
Kann mir ja vllt nochmal jmd helfen?

Grüße Ole

 

Hallo Ole,

benutze doch Autofilter und kopiere den sichbaren Bereich.

Gruß Hajo

 

Hallo,
Danke, aber das geht leider nicht. Ich versuche mein Problem anders zu erklären.
Ich habe eine Tabelle(Tabellenblatt A) mit Zahlen von 1-90(kein kommt doppelt vor).
Auf einem extra Tabellenblatt(Tabellenblatt B) kann ich einen Namen eingeben und dann sehe ich die Nummern bei dem der Name steht. Ich gebe z.B. Ole (auf Tabellenblatt B) ein und dann steht in Spalte A z.B. 1;5;23;24;55(Tabellenblatt B). Nun möchte ich alles was in der Zeile wo die 1;5 etc steht von Tabellenblatt A in das Tabellenblatt B hinter die jeweilige Zahl kopieren am besten automatisch mit einer Formel. Mit dem SVerweis klappt das nicht vernünftig und es gibt doch bestimmt eine andere Möglichkeit.
Deswegen funktioniert leider der Autofilter nicht :/

Gruß Ole

 

Hallo!

Ohne deinen genauen Aufbau zu kennen, tippe ich mal auf sowas:
http://excelformeln.de/formeln.html?welcher=28

 

Hey,
Irgendwie komme ich damit nicht weiter. Obwohl das einfach sein sollte

A B C
Ole 10 10
Rainer 20 50
Hendrik 30 10

Hendrik 50 20
Frank 15 15
Peter 12 25

Ole 30 60
Rainer 20 80
Peter 10 70

Dann gebe ich in einem neuen Tabellenblatt in C2 den Namen ein, z.b. Ole

Dann soll das so aufgelistet werden:
Ole 10 10
Ole 30 60

Wie bekomme ich das am leichtesten hin?
Mit Summenprodukt kann ich ja die ganzen Zahlen addieren.
Ich komme einfach nicht weiter.

Grüße Ole
P.S. Das ist ein Auszug, Mit einem Filter geht das leider nicht.

 

Hallo!

	A	B	C	D	E	F	G	H	I	J
1	Ole	10	10					Ole
2	Rainer	20	50
3	Hendrik	30	10					Ole	10	10
4								Ole	30	60
5	Hendrik	50	20
6	Frank	15	15
7	Peter	12	25
8
9	Ole	30	60
10	Rainer	20	80
11	Peter	10	70

Zelle	Formel
H3	{=INDEX(A:A;KKLEINSTE(WENN($A$1:$A$999=$H$1;ZEILE($1:$999));ZEILE($A1)))}
I3	{=INDEX(B:B;KKLEINSTE(WENN($A$1:$A$999=$H$1;ZEILE($1:$999));ZEILE($A1)))}
J3	{=INDEX(C:C;KKLEINSTE(WENN($A$1:$A$999=$H$1;ZEILE($1:$999));ZEILE($A1)))}
H4	{=INDEX(A:A;KKLEINSTE(WENN($A$1:$A$999=$H$1;ZEILE($1:$999));ZEILE($A2)))}
I4	{=INDEX(B:B;KKLEINSTE(WENN($A$1:$A$999=$H$1;ZEILE($1:$999));ZEILE($A2)))}
J4	{=INDEX(C:C;KKLEINSTE(WENN($A$1:$A$999=$H$1;ZEILE($1:$999));ZEILE($A2)))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

Danke Danke Danke Ich liebe dieses Forum!
Eins noch, gibt es eine Möglickeit den "Fehler" #Zahl! nciht anzeigen zu lassen?

 

Hallo!

Ja, auch dieser Fehlerabfang wird in meinem Link beschrieben...

=WENN(ZEILE(A1)>ZÄHLENWENN($A:$A;$H$1);"";INDEX(A:A;KKLEINSTE(WENN($A$1:$A$999=$H$1;ZEILE($1:$999));ZEILE($A1))))

 

Hallo nochmal,
Ich bin einfach zu blöd bin schon seit wieder über einer Std am ausprobieren.

=INDEX(Product_Roadmap!V:V;KKLEINSTE(WENN(Product_Roadmap!$V$1:$V$999=$C$2;ZEILE(Product_Roadmap!$1:$999));ZEILE($A13)))

Das ist meine Formel und mit deiner Formel müsste das so aussehen:

=WENN(ZEILE(A13)>ZÄHLENWENN(Product_Roadmap!$V:$V;$C$2);"";INDEX(Product_Roadmap!V:V;KKLEINSTE(WENN(Product_Roadmap!$V$1:$V$999=$C$2;ZEILE(Product_Roadmap!$1:$999));ZEILE($A13))))


Excel zeigt mir aber immer wieder ein Fehler an und lässt die Zelle dann Weiß. Das ist irgendwie komisch.

Weiß einfach nicht weiter

Gruß Ole

 

Hallo!

Zwei Möglichkeiten:
1. Du hast die Formel nicht mit Strg+Shift+Enter abgeschlossen
2. Dein Suchbegriff taucht weniger als 13x auf, denn hier suchst du nach dem 13. Treffer.

 

Ok nehmen wir das zweite! Jetzt hab ich auch endlich verstanden wofür das da ist. Danke!