Office: Datei mit Makro öffnen; Pfad auslesen???

Hallo,

ich habe eine Excel Datei, die ein Mkro beinhaltet- das wiederum eine andere Datei öffnet- diese Datei kann aber immer an einem anderen Ort bzw Pfad liegen. Kann ich mir irgendwie ein Excel Blatt bauen, in dem ich dem aktuellen Pfad, wo die Datei liegt in eine Zelle schreibe und das Makro dann die Zelle ausließt und die Datei in dem eingegebenen Pfad öffnet? Wenn ja, wie mache ich das???
Will nämlich nicht jedes mal in dem Makro die Pfade ändern. Oder hat noch jemand eine andere Idee wie man so etwas gut lösen kann?

mfg

 

Hallo,

wenn Du zB. im Arbeitsblatt "Tabelle1" folgenden Inhalt hast:

	A	B
1	Pfad:	C:\Exceldaten\2009
2	Datei:	Daten.txt
3

dann kannst Du Dir im VBA-Editor in einem allgem. Codemodul folgende Funktion anlegen:

Code:

Public Function Pfad_Datei(Blatt$) As String
  Dim Pfad As String
  Dim Datei As String
  
  With Worksheets(Blatt$)
    'Hole aus Zelle B1 den Pfad
    Pfad = .Range("B1").Value
    'Hole aus Zelle B2 den Dateinamen
    Datei = .Range("B2").Value
  End With
  'Überprüfe, ob Pfad am Ende einen "\" hat;
  'falls nicht füge ihn an
  If Right(Pfad, 1) <> "\" Then Pfad = Pfad & "\"
  'Gib beides Pfad+Dateiname als Rückgabewert aus der Funktion zurück
  Pfad_Datei = Pfad & Datei
End Function

Gibst Du zB. im Direktbereich des VBA-Editors Folgendes ein:

Code:

?pfad_datei("Tabelle1")

erhältst Du als Ergebnis:

Code:

C:\Exceldaten\2009\Daten.txt

Das Gleiche kannst Du natürlich auch an der Stelle in Deinem Makro, wo Du den Pfad+Dateinamen brauchst, machen:
Angenommen, die Variable, in der Du beides brauchst, lautet: Datei (vom Datentyp String)
dann kannst Du mit folgender Zuweisung
Datei=Pfad_Datei("Tabelle1")
Dir den Pfad+Dateinamen aus dem Arbeitsblatt "Tabelle1" aus den Zellen B1 und B2 abholen.

 

aller Anfang ist schwer

Hi, irgendwie klappt das nicht... ich bin leider noch nicht so fit mit Makros...
Ich bekomme immer folgende Fehlermeldung:

Fehler beim Kompilieren:
End Sub erwartet

[/code]
Sub Makro1()
'
' Makro1 Makro
' Makro am 27.11.2009 von Marius aufgezeichnet
'

'
Public Function Pfad_Datei(Blatt$) As String
Dim Pfad As String
Dim Datei As String

With Worksheets(Blatt$)
'Hole aus Zelle B1 den Pfad
Pfad = .Range("B1").Value
'Hole aus Zelle B2 den Dateinamen
Datei = .Range("B2").Value
End With
'Überprüfe, ob Pfad am Ende einen "\" hat;
'falls nicht füge ihn an
If Right(Pfad, 1) <> "\" Then Pfad = Pfad & "\"
'Gib beides Pfad+Dateiname als Rückgabewert aus der Funktion zurück
Pfad_Datei = Pfad & Datei

End Function

End Sub


Ist das mit den Subs überflüssig?
und wie öffne ich dann die datei mit dem makro? das müßte ddich irgendwie so aussehen:

Workbooks.Open Filename:="?pfad_datei("Tabelle1")"

und wie bekommst du das so schön hin mit der eingeblendeten tabelle und dem extra feld für den code???

mfg

 

Hallo,

in Visual Basic gibt es keine geschachtelten Functions/Subs (so wie in Pascal). Daher musst Du unbedingt
1) am Anfang die Zeile, in der steht Sub Makro1() , entfernen;
2) am Ende die Zeile, in der steht End Sub , entfernen.
Die Zeilen, die mit einem einfachen Hochkomma ' beginnen, stellen Kommentar dar, sind somit nur für einen menschlichen Leser bestimmt und werden vom Compiler ignoriert. Diese Zeilen kannst Du stehen lassen oder entfernen (je nach Deinen Bedürfnissen).

Ferner muss die Workbooks.Open-Methode folgendermaßen lauten:
Workbooks.Open Filename:=Pfad_Datei("Tabelle1")
(also ohne die äußeren 2 Anführungszeichen und ohne das Fragezeichen)

Anmerkung:
Das Fragezeichen darf man nur im Direktbereich des VBA-Editors benutzen und ist dort nur die Kurzschreibweise für "DEBUG.PRINT": mit dieser Anweisung kann man VBA veranlassen, eine Ausgabezeile im Direktbereich mit den Ausdrücken zu produzieren, die nach dem Fragezeichen kommen - in normalen VBA-Code hat daher das "DEBUG.PRINT" und damit auch das Fragezeichen nichts verloren.
Der Direktbereich ist ein Fenster innerhalb des VBA-Editors. Falls dieses Fenster bei Dir nicht sichtbar sein sollte, so kann man es über das Menü Ansicht > Direktfenster (oder Tastenkombination Strg+G) einblenden.
Dieser Bereich ist ein Rest aus den Zeiten von MS-DOS, wo es nur zeichenorientierte Bildschirm/Druck-Ausgabe gab. Damals steuerte die PRINT-Anweisung diese Ausgabe. In diesem Bereich kann man auch jetzt noch auf die Schnelle testen, ob eine Funktion die korrekten Resultate liefert.

EDIT:
1) Das Extra-Feld für den Code ist einfach zu erzeugen:
a) Im Eingabefenster den Text markieren, den man in diesem Codefenster haben will
b) Auf den Button mit der Aufschrift "Code" klicken. Daraufhin sieht das Ganze folgendermaßen aus:
[ code]Text...[/code ]
(Ich musste 2 Leerzeichen hineinschwindeln, damit die Codierung nicht aktiv wird) Das Ganze nennt sich BBCode und hat Ähnlichkeiten mit HTML-Tags bzw. XML-Tags. Wie Du siehst, gibt es noch eine Reihe weiterer Buttons.

2) Die eingeblendete Tabelle (und eventuell eine 2. Tabelle mit den Formelauflistungen) kann man erzeugen, wenn man ein Add-In in Excel installiert. Dieses Add-In kann man von folgender Site downloaden - Du musst etwas lesen, es gibt dort offensichtlich eine Reihe von Varianten:
http://www.office-loesung.de/ftopic270473_255_0_asc.php

 

Danke, es hat geklappt- genau so wie ich es mir vorgestellt hab!

Und ich bin auch um einiges schlauer geworden!!

Also, besten Dank!!!!

 

Hallo,
hoffe es passt so, dass ich meine Frage hier anschließe, da diese mit dem Thema zusammenhängt.
Meine Excel-Makrokenntnisse sind gleich null; mal vorweg. Folgendes Makro habe ich mühsamst aus Foren zusammengeschustert:

-------------------------------------------------
Sub Öffnen()

Dim strPfad As String

strPfad = _
Worksheets("LINK").Range("B1").Text

Application.Workbooks.Open (strPfad)

Workbooks("WOPL.xlsm").Close savechanges:=False

End Sub
-----------------------------------------------------------

Kurze Erklärung:
Wir haben ein Planungstool auf Excelbasis gehabt, welches das ganze Jahr beinhaltet und auf einem Server lag. Da mehrere gleichzeitig darauf zugreifen und die Exceldatei recht groß war habe ich dieses auf die Monate aufgeteilt. Um benutzerfreundlich zu sein, habe ich diese Exceldatei mit dem obrigen Makro erstellt.
Diese öffnet anhand des Datums, die Richtige Datei (somit kann man sich auf dem Desktop eine Verküpfung erstellen und man muss sich nicht auch noch im Ordner die Datei suchen).
Der Pfad zu der Datei steht (wie im Makro ersichtlich) in der Zelle B1.

Nun zu meinem "Problem"-chen:

Die Datei (z.B. Jänner) enthält für jede Kalenderwoche ein Tabellenblatt (z.B. KW2).
Nun wäre es super wenn das obere Makro noch das Richtige Tabellenblatt öffnet (also die aktuelle KW2).
Der Name des Tabellenblatts, steht in der Exceldatei mit dem Makro, in der Zelle B4.

Ich hoffe ich habe es soweit gut erklärt.

LG Christoph

Edit: habe vergessen zu erwähnen, dass es sich hierbei um Excel 2010 handelt.

 

Hallo Christoph,

dein Makro habe ich wie folgt ergänzt und es mit reichlich Kommentar versehen, sodass es einigermaßen verständlich sein sollte:

Code:

Sub Öffnen()

   Dim strPfad As String
   Dim KW As Integer, FehlNr As Integer

   On Error GoTo Err_Öffnen
  
   'Ermittelt in "strPfad" den Pfad zur Excel-Arbeitsmappendatei
   FehlNr = 0
   strPfad = Worksheets("LINK").Range("B1").Value
   
   
   'Öffnet die Datei in Variable "strPfad" als aktive neue Excel-Arbeitsmappe
   FehlNr = 1
   Application.Workbooks.Open(Filename:=strPfad).Activate
   
   '1) Diese Arbeitsmappe enthält mehrere Arbeitsblätter mit den Kalenderwochen als Blattnamen im Format "KW#"
   '2) Das Blatt der aktuellen Kalenderwoche soll aktiviert werden.
   '3) Die aktuelle Kalenderwoche wird nach der europäischen Norm (ISO 8601) ermittelt (also nicht nach USA-Methode):
   '   a) Die Woche beginnt mit dem Montag als erstem Tag der Woche - der Sonntag ist somit der 7. Tag
   '   b) Die erste Kalenderwoche eines Jahres (KW1) liegt in demjenigen Kalenderjahr, in dem der erste Donnerstag liegt
   '      (z.B. reicht KW1 für "2015" von 29.12.2014 bis 04.01.2015, da der 1.Donnerstag auf den 1.1.2015 fällt !!)
   '   c) Vorausgesetzt dafür wird mindestens Excel2010.
   '4) Zur Ermittlung der KW auf Basis von Punkt 3) wird das heutige Datum gewählt
   '
   KW = WorksheetFunction.WeekNum(Date, 21) 'Europ.Methode wie unter 3) beschrieben (Excel2010 !!)
   'KW = WorksheetFunction.WeekNum(Date, 1) 'falls die USA-Methode gewünscht sein sollte
   
   'Kalenderwochenarbeitsblatt KW# wird aktiviert und Zelle A1 darin selektiert
   FehlNr = 2
   ActiveWorkbook.Sheets("KW" & KW).Activate
   ActiveSheet.Range("A1").Select
  
   'Geöffnete Arbeitsmappe "WOPL.xlsm" wird geschlossen, ohne sie zu speichern.
   FehlNr = 3
   Workbooks("WOPL.xlsm").Close SaveChanges:=False
   
   Exit Sub
   
'Fehlerbehandlungsabschnitt für 4 Fehlertypen:
Err_Öffnen:
   Select Case FehlNr
      Case 0: MsgBox Prompt:="Das Arbeitsblatt 'LINK' konnte nicht gefunden werden.", _
                     Buttons:=vbCritical + vbOKOnly, Title:="Fehlendes Arbeitsblatt"
      Case 1: MsgBox Prompt:="Der Pfad '" & strPfad & "' konnte nicht gefunden werden.", _
                     Buttons:=vbCritical + vbOKOnly, Title:="Falscher Arbeitsmappenpfad"
      Case 2: MsgBox Prompt:="Das Arbeitsblatt 'KW" & KW & "' konnte nicht gefunden werden.", _
                     Buttons:=vbCritical + vbOKOnly, Title:="Fehlendes Kalenderwochenblatt"
      Case 3: MsgBox Prompt:="Die Arbeitsmappe 'WOPL.xlsm' konnte nicht geschlossen werden.", _
                     Buttons:=vbCritical + vbOKOnly, Title:="Nicht geöffnete Arbeitsmappe"
   End Select
  
End Sub

Mit in den Code aufgenommen habe ich eine einfache Fehlerbehandlung, falls diverse Teile nicht gefunden werden können.
Im Fehlerfall wird das Makro mit entsprechender Meldung beendet ohne weitere Maßnahmen.

 

Hallo Exl121150,

danke für die Antwort :)

ich hab mich nur mitlerweile ebenfalls selbst durchgewurstet.

Code:

Sub Öffnen()

Dim strPfad1 As String, strPfad2 As String
strPfad1 = _
Worksheets("LINK").Range("B1").Text

strPfad2 = _
Worksheets("LINK").Range("B4").Text

Application.Workbooks.Open (strPfad1)

Sheets(strPfad2).Select


Workbooks("WOPL.xlsm").Close savechanges:=False

End Sub

die Fehlerbehandlung finde ich auch eine gute Idee.
Habe deinen Code auch gleich mal ausprobiert und da ist folgender Fehler aufgetreten:
Die Kalenderwochen sind immer mit 2 Ziffern (z.B.: KW02) und das Makro hat daher das Blatt nicht gefunden.
In der Zelle B4 steht auch "KW02". War aber wahrscheinlich auch mein fehler, da ich verabsäumt habe dies zu erwähnen.

Ich danke dir trotzdem für deine Antwort :)

LG Christoph

 

Hallo,

an der rot gekennzeichneten Stelle die Änderung durchführen, um die korrekte Arbeitsblattbezeichnung zu erhalten:

Code:

Sub Öffnen()

   Dim strPfad As String
   Dim KW As Integer, FehlNr As Integer

   On Error GoTo Err_Öffnen
  
   'Ermittelt in "strPfad" den Pfad zur Excel-Arbeitsmappendatei
   FehlNr = 0
   strPfad = Worksheets("LINK").Range("B1").Value
   
   
   'Öffnet die Datei in Variable "strPfad" als aktive neue Excel-Arbeitsmappe
   FehlNr = 1
   Application.Workbooks.Open(Filename:=strPfad).Activate
   
   '1) Diese Arbeitsmappe enthält mehrere Arbeitsblätter mit den Kalenderwochen als Blattnamen im Format "KW#"
   '2) Das Blatt der aktuellen Kalenderwoche soll aktiviert werden.
   '3) Die aktuelle Kalenderwoche wird nach der europäischen Norm (ISO 8601) ermittelt (also nicht nach USA-Methode):
   '   a) Die Woche beginnt mit dem Montag als erstem Tag der Woche - der Sonntag ist somit der 7. Tag
   '   b) Die erste Kalenderwoche eines Jahres (KW1) liegt in derjenigen Woche, in der der erste Donnerstag liegt
   '      (z.B. reicht KW1 für "2015" von 29.12.2014 bis 04.01.2015, da der 1.Donnerstag auf den 1.1.2015 fällt !!)
   '   c) Vorausgesetzt dafür wird mindestens Excel2010.
   '4) Zur Ermittlung der KW auf Basis von Punkt 3) wird das heutige Datum gewählt
   '
   KW = WorksheetFunction.WeekNum(Date, 21) 'Europ.Methode wie unter 3) beschrieben (Excel2010 !!)
   'KW = WorksheetFunction.WeekNum(Date, 1) 'falls die USA-Methode gewünscht sein sollte
   
   'Kalenderwochenarbeitsblatt KW# wird aktiviert und Zelle A1 darin selektiert
   FehlNr = 2
   ActiveWorkbook.Sheets("KW" & [COLOR="#FF0000"]Format(KW,"00")[/COLOR]).Activate
   ActiveSheet.Range("A1").Select
  
   'Geöffnete Arbeitsmappe "WOPL.xlsm" wird geschlossen, ohne sie zu speichern.
   FehlNr = 3
   Workbooks("WOPL.xlsm").Close SaveChanges:=False
   
   Exit Sub
   
'Fehlerbehandlungsabschnitt für 4 Fehlertypen:
Err_Öffnen:
   Select Case FehlNr
      Case 0: MsgBox Prompt:="Das Arbeitsblatt 'LINK' konnte nicht gefunden werden.", _
                     Buttons:=vbCritical + vbOKOnly, Title:="Fehlendes Arbeitsblatt"
      Case 1: MsgBox Prompt:="Der Pfad '" & strPfad & "' konnte nicht gefunden werden.", _
                     Buttons:=vbCritical + vbOKOnly, Title:="Falscher Arbeitsmappenpfad"
      Case 2: MsgBox Prompt:="Das Arbeitsblatt 'KW" & KW & "' konnte nicht gefunden werden.", _
                     Buttons:=vbCritical + vbOKOnly, Title:="Fehlendes Kalenderwochenblatt"
      Case 3: MsgBox Prompt:="Die Arbeitsmappe 'WOPL.xlsm' konnte nicht geschlossen werden.", _
                     Buttons:=vbCritical + vbOKOnly, Title:="Nicht geöffnete Arbeitsmappe"
   End Select
  
End Sub

 

Etwas anderes Problem

Moin,

Ich möchte mit einer Schaltfläche auf "Tabellenblatt1" ein Makro ansteuern (Vorgehensweise noch bekannt).
Dieses Makro soll einen Hyperlink (PDF-Datei) auf "Tabellenblatt2" Zelle A1 öffnen.
"Tabellenblatt2" soll hierbei nach Möglichkeit nicht angezeigt werden.
Problem ist, dass der Inhalt von "Tabellenblatt2" immer mal wieder angepasst wird.
Excel-Datei und PDF-Dateien sollen im Gleichen Grundordner liegen. Optimal wäre wenn die Zuordnung ohne Definition des gesamten Dateipfad möglich wäre, da der Ordner ohne Änderungen auf verschiedene Rechner kopiert werden soll.

Vielen Dank schon mal.

p.s.: Ich weiß, dass da auch was mit Datenbanken geht. Das bekomme aber weder ich noch die geplanten Nutzer bearbeitet.

 

Hallo,

ich habe dir eine Excel-Datei mit Makro beigelegt, die ich gemäß deinen Wünschen angelegt habe.

Den Hyperlink in Zelle A1 von Tabellenblatt2 musst du zuerst natürlich an deine Verhältnisse anpassen. Dabei ist natürlich nicht entscheidend, was als Hyperlinktext angezeigt wird, sondern was als Hyperlinkadresse (eigentlicher Inhalt des Hyperlinks) abgespeichert wird. Dieser Hyperlinkinhalt muss den Pfad (samt Laufwerk) und den Dateinamen der PDF-Datei enthalten. Als Pfad ist auch die UNC-Variante erlaubt.
In meinem Beispiel ist der angezeigte Hyperlinktext: S:\Dokumente\MODULE1.pdf
und der Hyperlinkinhalt (als UNC-Variante): \\ts1\daten\Benutzer\Anton Exl\Dokumente\MODULE1.pdf

Darüber hinaus musst du (wahrscheinlich) den Pfad zum Adobe-Acrobat-Reader an deine Dateisystem-Verhältnisse anpassen. In meinem Dateisystem lautet dieser Pfad "C:\Program Files (x86)\Adobe\Reader 11.0\Reader\", wobei ich den Adobe-Reader XI installiert habe (Datei: AcroRd32.exe). Ich habe dir eine 2. Version dieses Pfades als Kommentarzeile ins Makro gestellt.

Der Aufruf des Readers zwecks Anzeige der PDF-Datei in einem normalen Fenster mit Fokus erfolgt in VBA mit der Shell-Funktion, wobei der 1. Parameter den eigentlichen Aufrufbefehl, wie er im Betriebssystem vorzunehmen ist, enthält. Nach meinen vorhin erwähnten Vorgaben lautet dieser:
"C:\Program Files (x86)\Adobe\Reader 11.0\Reader\AcroRd.exe" "\\ts1\daten\Benutzer\Anton Exl\Dokumente\MODULE1.pdf"
wobei die Anführungszeichen wichtig sind, damit das Betriebssystem weiß, welche Bestandteile zum Pfad+Programm gehören und was andererseits zu den Aufrufparametern des Programms gehört. Denn als Trennzeichen zwischen Programm und Parametern gilt auf Betriebssystemebene das Leerzeichen. Enthält jedoch der Pfad selbst Leerzeichen (was in meinem Beispiel der Fall ist), müssen diese Teile in Anführungszeichen gesetzt werden, damit das Betriebssystem nicht zu der irrigen Überzeugung gelangt, dass alles, was auf das 1. Leerzeichen (also alles ab "Files") folgt, zu den Programmaufrufparametern gehört.