Office: Dateinamen in Zelle anzeigen ohne den Pfad

Hallo Leute.

Weiß jemand die Formel um den Dateinamen anzuzeigen, die gibt es nur ich weiß Sie nicht mehr und finde Sie nirgends.

Finde nur die Formel wo der komplette Pfad angezeigt wird und der Name des Arbeitsblatts.

Weiß jemand die Formel???

Danke

 

Hi

also in der seitenansicht unter kopf/fußzeile kannst du den Dateinamen in die kop/fußzeile einfügen lassen indem du auf das zweite Symbol von rechts klickst (blatt mit excel-zeichen). dann wird der dateiname auf den seiten angezeigt.

gruß

 

das weiß ich, aber ich möchte ihn in einer Zelle anzeigen lassen.

 

sorry, k. a. wie das geht...

 

Hallo!

Kopiere diese Formel in deine Zelle.

=TEIL(ZELLE("Dateiname");1+FINDEN("[";ZELLE("Dateiname"));FINDEN("]";ZELLE("Dateiname"))-FINDEN("[";ZELLE("Dateiname"))-1)

Funktioniert allerdings erst, wenn die Mappe vorher gespeichert wurde.

 

Hallo,

habe ein ähnliches Problem. Die Formel von Schatzi funktioniert schon super, aber wie kann ich sie anpassen, so dass nur die letzten 6 Ziffern des Dateinamens angezeigt werden??

Oder gibt es eine Möglichkeit von dem angezeigten Namen nur die Zahlen anzeigen zu lassen. so dass zb: Rechnung-Herbert-Müller-034214 zu 034214 wird??

Lieben Gruß,
max

 

Hallo!

Teste mal dies:

=TEIL(ZELLE("Dateiname");FINDEN("]";ZELLE("Dateiname"))-10;10)
(mit .xls)
=TEIL(ZELLE("Dateiname");FINDEN("]";ZELLE("Dateiname"))-10;6)
(ohne .xls)

 

Danke!!

funktioniert bestens genau was ich suchte und Dank den zwei Beispielen habe ich nun auch durchschaut wie ich es anpassen kann.

Liebe Grüße,
max

 

Registername anzeigen

Eine kleine Erweiterung dieses Problems: Wie schaffe ich, dass auf meinem Blatt (nicht in der Kopf- bzw. Fußzeile) in einer bestimmten Zelle der Name des Blattes bzw. Registers angezeigt wird?

Gruß

 

Hallo Andei!

Menü Einfügen > Namen > Definieren
Name: Blatt
Bezieht sich auf: =DATEI.ZUORDNEN(1+0*JETZT())

Nun diese Formel in eine beliebige Zelle:

=TEIL(Blatt;FINDEN("]";Blatt)+1;99)

Oder ohne Namensvergabe:

=TEIL(ZELLE("Dateiname");FINDEN("]";ZELLE("Dateiname"))+1;99)

Das Wort "Dateiname" bleibt so stehen!!! (Es wird also nicht durch den tatsächlichen Namen ersetzt.)

 

Hi Schatzi,

schon mal danke für die schnelle Hilfe. Ein kleines Problem bleibt bestehen: Die Formel (habe mal die ohne Namensvergabe verwendet) zieht immer nur den Namen des Registers an, das zuletzt bearbeitet wurde. D.H. wenn ich sie jetzt in mehrere Registerblätter einfüge (ich will das ja dann mal auf dem Ausdruck stehen haben), steht in allen Registern der gleiche Name :-(

Werd's mal noch mit der Namensvergabe probieren...

Gruß

 

Stimmt!

Ändere die Formel mal in

=TEIL(ZELLE("Dateiname";A1);FINDEN("]";ZELLE("Dateiname";A1))+1;99)

Dann müsste es klappen.

 

Habs jetzt mit dem Namen geklappt, das funktioniert wunderbar!

Kannst Du so aus dem Stehgreif sagen, ob das auch noch funktioniert, wenn ich daraus ne Excel-Vorlage, also ne .xlt mache?

 

Ja, das müsste eigentlich auch klappen, aber 100% sicher bin ich mir da nicht.

Versuch macht kluch...

 

Sööö,

Versuch machte wirklich kluch, es funktioniert, allerdings bekommt man nach dem Öffnen ein "#Wert", der Registername erscheint erst nach Bearbeiten/Speichern des Blattes.

Werde jetzt im Finaldokument Deine Version 2 der Formel ohne Namen verwenden, die klappt wunderbar!

Herzlichen Dank!