Office: Datenbankfenster mit VB Ein- und Ausblenden

CobraHome · 13. September 2003

Hallo,

ich möchte das Datenbankfenster mit VBA Ein - bzw. Ausblenden wenn
ich z.b. auf einen Button klicke ....

Ich kann nur irgendwie ( wenn es überhaupt möglich ist ) die Eigenschaft
nicht finden .... sowas wie :

Datenbankname.Datenbankfenster.enabled = true

Vielen Dank

Grüße

Cobra

:)

BodoM · 15. September 2003

Hallo,

hier die gewünschte Funktion und noch ein paar andere. Ist aus der OL-Hilfe.
Code:

Sub Datenbank_Sperren()
ÄndernEigenschaft "StartupShowDBWindow", dbBoolean, False
ÄndernEigenschaft "StartupShowStatusBar", dbBoolean, True
ÄndernEigenschaft "AllowBuiltinToolbars", dbBoolean, False
ÄndernEigenschaft "AllowFullMenus", dbBoolean, False
ÄndernEigenschaft "AllowBreakIntoCode", dbBoolean, False
ÄndernEigenschaft "AllowSpecialKeys", dbBoolean, False
ÄndernEigenschaft "AllowBypassKey", dbBoolean, False
End Sub

Sub Datenbank_Entsperren()
ÄndernEigenschaft "StartupShowDBWindow", dbBoolean, False
ÄndernEigenschaft "StartupShowStatusBar", dbBoolean, True
ÄndernEigenschaft "AllowBuiltinToolbars", dbBoolean, True
ÄndernEigenschaft "AllowFullMenus", dbBoolean, True
ÄndernEigenschaft "AllowBreakIntoCode", dbBoolean, True
ÄndernEigenschaft "AllowSpecialKeys", dbBoolean, True
ÄndernEigenschaft "AllowBypassKey", dbBoolean, True
End Sub

Function ÄndernEigenschaft(strEigenschaftenname As String, varEigenschaftentyp As Variant, varEigenschaftenwert As Variant) As Integer
On Error GoTo Err_ÄndernEigenschaft
Dim db As Database, prp As Property
Const conPropNotFoundError = 3270
Set db = DBEngine(0)(0)
db.Properties(strEigenschaftenname) = varEigenschaftenwert
ÄndernEigenschaft = True
Exit_ÄndernEigenschaft:
Exit Function
Err_ÄndernEigenschaft:
If Err = conPropNotFoundError Then
Set prp = db.CreateProperty(strEigenschaftenname, varEigenschaftentyp, varEigenschaftenwert)
db.Properties.Append prp
Resume Next
Else
ÄndernEigenschaft = False
Resume Exit_ÄndernEigenschaft
End If
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Die gewünscht Fkt. ist StartupShowDBWindow

Gruß Bodo

BodoM · 15. September 2003

Oh, ich habe vergessen zu erwähnen, dass Du Dir unbedingt eine Möglichkeit offen halten musst die Fkt. Entsperren aufzurufen, wenn Du alle Einstellungen änderst.

Ich lege mir dafür in ein Formular ein Button an der nicht sichtbar ist.

CobraHome · 15. September 2003

Wow das ging aber Fix *wink.gif*

Vielen Dank !

Ciao

Cobra

BodoM · 15. September 2003

Ich hoffe, Du hast meine Ergänzug gelesen.

Sascha Trowitzsch · 15. September 2003

Das ging zwar fix, ist aber wohl nicht die richtige Antwort, wenn ich die Frage recht verstanden habe.
(@bodo: Die Eigenschaftenänderungen deines Codes wirken sich erst beim nächsten Öffnen der DB aus. Ein Ausführen des Codes per Button schließt/öffnet nicht das Datenbankfenster.)

Das Datenbankfenster kann man nicht per VBA anzeigen/ausblenden.
Das ginge nur mit einer API-durchwirkten Extrafunktion... Just some seconds, soon available ... *wink.gif*

Ciao, Sascha

racoon0506 · 15. September 2003

...evtl. API-Funktion bei donkarl
FAQ 1.11

Sascha Trowitzsch · 15. September 2003

Wg. donkarl 1.11:

Ich gehe davon aus, dass die Nomenklatur von Cobras Beitrag korrekt war. Dann ist das Datenbankfenster aber nicht das Access-Hauptfenster...

Für das Datenbankfenster:
Code:

Option Compare Database
Option Explicit

Private Declare Function EnumChildWindows Lib "user32" (ByVal hWndParent As Long, _
ByVal lpEnumFunc As Long, ByVal lparam As Long) As Long
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, _
ByVal lpClassName As String, ByVal nMaxCount As Long) As Long
Private Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, _
ByVal nCmdShow As Long) As Long

Private DBhwnd As Long

Public Sub DatenbankfensterVisible(b As Boolean)
Dim res As Long
res = EnumChildWindows(Application.hWndAccessApp, AddressOf ChildProc, 0)
If DBhwnd = 0 Then Exit Sub
ShowWindow DBhwnd, CLng(Abs(b))
End Sub

Private Function ChildProc(ByVal hwnd As Long, ByVal lparam As Long) As Long
Dim sClass As String, n As Long

sClass = String(255, vbNullChar)
n = GetClassName(hwnd, sClass, 255)
If n > 0 Then sClass = Left(sClass, n)
If sClass = "ODb" Then DBhwnd = hwnd
ChildProc = 1
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Diesen Code in ein neues Modul setzen. Aufruf mit:

DatenbankfensterVisible True zeigt es an.
DatenbankfensterVisible False blendet es aus.

Ciao, Sascha

PS: Das geht in der dargestellten Form nur mit A2000/XP!!! Falls Code für A97 nötig:
Unter http://www.access-paradies.de/tipps/...access_97_.php den Teil zu AddrOf ein ein zusätzliches Modul kopieren und oben die Zeile:
Code:

res = EnumChildWindows(Application.hWndAccessApp, AddressOf ChildProc, 0)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ändern in:
Code:

res = EnumChildWindows(Application.hWndAccessApp, AddrOf("ChildProc"), 0)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Sascha Trowitzsch · 15. September 2003

Shit happens!

Das Ausblenden des Datenbankfensters geht sehr einfach auch mit:

Docmd.RunCommand acCmdWindowHide

Das Einblenden mit

Docmd.RunCommand acCmdWindowUnhide

führt allerdings dazu, dass erst der Dialog "Fenster einblenden..." erscheint, den man Bestätigen muss. Man kann den Dialog auch nicht mit SendKeys automatisieren.
Mein API-Modul verliert deshalb *entsetzt nicht seine Berechtigung.

Ciao, Sascha

User · 2. Januar 2011

\@Sascha:

Den Dialog "Fenster einblenden..." kann man vermeiden, indem man zum erneuten einblenden statt

Docmd.RunCommand acCmdWindowUnhide

einen Tastendruck simuliert

Sendkeys "{F11}"

Habs getestet und es funktioniert bei mir zumindest doch :-D

Ciao Stefan

JPA · 2. Januar 2011

\@Stefan
F11 geht aber nicht mehr, wenn die speizialtasten deaktiviert wurden.

Frank200 · 3. Januar 2011

Hallo Sascha,

bei der Analyse Deines Codes fiel mir auf, daß Du die Funktion ChildProc() aufrufst, ohne die Parameter hwnd und lparam zu übergeben, die beide nicht optional sind. Danach stutzte ich über AddressOf, testete die VBA-Hilfe und mir wurde klar, daß Du mal wieder eine dankesnwerte Anregung gibst, etwas Neues zu lernen *wink.gif*

Betreffs AddressOf werde ich mich gern selbst einlesen und versuchen, zu verstehen, was da passiert. Ich lög, wenn ich behaupten würde, die VBA-Hilfe beim ersten Lesen verstanden zu haben.

Doch läst sich mit wenigen Worten sagen, wo für den Aufruf von ChildProc() die Parameterwerte herkommen? "AddressOf ChildProc" ist zwar kein klassischer Aufruf, aber die Funktion ChildProc noch immer eine benutzerdefinierte Funktion... ???

achtelpetit · 3. Januar 2011

Falls es darum geht, die User am Rumfummeln zu hindern, starte die User-Frontends mit dem Schalter "/runtime". Dann verhält sich Access auch bei einer Vollinstallation wie eine Runtime, und da ist für den User nix zu Fummeln.

Sascha Wagner · 19. April 2013

Geht auch einfacher :-)

'einblenden
DoCmd.SelectObject acTable, , True

'ausblenden
DoCmd.SelectObject acTable, , True
RunCommand acCmdWindowHide

Office: Datenbankfenster mit VB Ein- und Ausblenden

Datenbankfenster mit VB Ein- und Ausblenden

Datenbankfenster mit VB Ein- und Ausblenden

Datenbankfenster mit VB Ein- und Ausblenden

Datenbankfenster mit VB Ein- und Ausblenden

Datenbankfenster mit VB Ein- und Ausblenden

Datenbankfenster mit VB Ein- und Ausblenden - Similar Threads - Datenbankfenster Ausblenden

Tabellenränder beim Druck ausblenden

Kalender Termine ausblenden

Datum markieren und Daten ausblenden

VBA Code für Zeilen ausblenden einblenden mit JA/Nein

Musik ausblenden beim speichern als Video

Bedingte Formatierung / Wiederholungen "ausblenden"

Datenbankfenster ausblenden + Bildschirmaktualisierung ausschalten