Office: (Office 2007) Diagramm als separates Popup öffnen

Lucky-Striker · 22. Oktober 2008

Hallo Zusammen,

ich möchte gerne folgendes erreichen:

Ein Diagramm ist im Kleinformat in einer Arbeitsmappe eingebunden. Nun möchte ich per Mausklick auf das Diagramm, dass sich ein separates Fenster (nur das Diagramm in big, keine Menüs, etc.) über die geöffnete Arbeitsmappe legt und wenn ich wieder auf das große Diagrammfenster klicke, das Fenster geschlossen wird und ich auf dem ursprünglichen Datenblatt weiterarbeiten kann.

Prinzipiell Miniaturansicht Diagramm in separatem Fenster in groß darstellen! ;-)

Ich finde so gar nichts darüber in der weiten Welt des Inet und kann mir eigentlich nicht vorstellen, dass mein Wunsch nach der Funktion so selten ist...hhm!*rolleyes.gif*

Nun denn, für schnelle Hilfe bereits im Vorfeld besten Dank.

Gruss
Timo

:)

EarlFred · 24. Oktober 2008

Hallo Timo,

Du könntest das Diagramm in Kleinformat einmal kopieren (Strg+Drag&Drop ins selbe Blatt) und dem Duplikat mit Rechtsklick den Speicherort "Als Neues Blatt" angeben.

Dann fügst Du folgendes Makro in ein Allgemeines Modul

Code:

Sub DiagrammGross()
Sheets("Diagramm1").Activate
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

wobei der Name "Diagramm1" noch Deinem Namen angepasst werden muss.

Wieder mit Rechtsklick auf Dein "Mini-Diagramm" weist Du dieses Makro zu.

Auf Ebene des neuen Diagrammblatts fügst Du folgendes Makro ein:

Code:

Private Sub Chart_MouseDown(ByVal Button As Long, ByVal Shift As Long, ByVal x As Long, ByVal y As Long)
Sheets("Tabelle1").Activate
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Auch hier muss "Tabelle1" Deinem tatsächlichen Blattnamen angepasst werden.

Jetzt sollte das erstmal funktionieren.

Wenn es unbedingt ein Popup sein soll, wird's etwas komplizierter. Schreib einfach nochmal, wenn Dir die Lösung so nicht gefällt.

Grüße
EarlFred

Lucky-Striker · 24. Oktober 2008

Hallo EarlFred,

thx für die schnelle Antwort!

Deine Variante habe ich bereits so im Einsatz, wobei ich die "kompliziertere Variante" durchaus vorziehen würde, wenn ich wüsste wie! :-)

Hat den Hintergrund, dass diese Mappe einen ROI Rechner zum Einsatz beim Kunden enthält. Daher lege ich den optischen Maßstab etwas höher an. Für mich intern würde die geschilderte Variante reichen!

Gruss Timo

EarlFred · 24. Oktober 2008

Moin Timo,

gut, dann los *wink.gif*

Entweder:
Userform erstellen und in der "Werkzeugsammlung" das Steuerelement "MS Office Chart x.xx" nutzen.

Oder

1) Userform einfügen. Größe und Rest egal, machen wir über Code.
2) Folgenden Code in ein allgemeins Modul (speichert das Diagramm als Grafik auf Festplatte, nachdem es temporär in der Größe geändert wurde)

Code:

Sub Variante1()
Dim Diagramm As ChartObject
Dim lngWidth As Long, lngHeight As Long
Set Diagramm = Tabelle1.ChartObjects(1)
Application.ScreenUpdating = False
With Diagramm
lngWidth = .Width
lngHeight = .Height
.Height = Application.Height
.Width = Application.Width
.Chart.Export Filename:="C:\Temp\Diagramm.gif"
.Height = lngHeight
.Width = lngWidth
End With
Application.ScreenUpdating = True
UserForm1.Show
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

3) Folgenden Code hinter Deine Userform aus 1)

Code:

Private Sub UserForm_Initialize()
Me.Height = Application.Height
Me.Width = Application.Width
Me.Picture = LoadPicture("C:\TEMP\Diagramm.gif")
Me.PictureSizeMode = fmPictureSizeModeStretch
End Sub
Private Sub UserForm_Click()
Unload Me
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Besser so?

Grüße
EarlFred

Lucky-Striker · 24. Oktober 2008

Hah, EarlFred mein Held des Tages! *Smilie

Super, so habe ich mir das (...fast...) vorgestellt!

Schäme mich ja fast zu fragen...

...zwei Punkte hätte ich da noch!

Jetzt ist das Bild des Diagramms ja Vollbild, heisst es verdeckt alles bis zum nächsten Klick. Kriegt man das auch auf 50% der Vollbildgröße?

Und der Fensterrahmen, kann man den auch noch wegkriegen? Brauche ja keine Titelleiste und rotes Kreuz zum schließen, Klick genügt ja.

Grüße Timo

EarlFred · 24. Oktober 2008

Hallo Timo,

naja, der erste Teil ist nun wirklich nicht schwer:

Code:

Private Sub UserForm_Initialize()
Me.Height = Application.Height / 2
Me.Width = Application.Width / 2
Me.Picture = LoadPicture("C:\TEMP\Diagramm.gif")
Me.PictureSizeMode = fmPictureSizeModeStretch
Me.Caption = "Ein Diagramm"
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ach, die "Caption" habe ich noch beispielhaft geändert, damit da nicht immer "Userform" steht *wink.gif*

Beim zweiten Teil muss ich passen, wenn es eine Userform sein soll *frown.gif*

Da ginge dann nur noch, die bereits erstellte Grafik "Diagramm.Gif" als Bild in die Mappe einzufügen und bei Klick wieder zu löschen.... Aber willst Du das so haben?

Grüße
EarlFred

EarlFred · 24. Oktober 2008

Hallo Timo,

als Idee:

Code:

Option Explicit
Dim Bild As Picture
'******************************************
'*** Diagramm als Bild in Blatt ***
'******************************************
Sub DiagrammGross_alsBild()
Dim Diagramm As ChartObject
Dim lngWidth As Long, lngHeight As Long
Set Diagramm = Tabelle1.ChartObjects(1)
Application.ScreenUpdating = False
With Diagramm
lngWidth = .Width
lngHeight = .Height
.Height = Application.Height
.Width = Application.Width
.Chart.Export Filename:="C:\Temp\Diagramm.gif"
.Height = lngHeight
.Width = lngWidth
End With
Set Diagramm = Nothing

Set Bild = ActiveSheet.Pictures.Insert("C:\Temp\Diagramm.gif")
With Bild
.Height = Application.Height / 2
.Width = Application.Width / 2
.Left = Application.Width / 4
.Top = Application.Height / 5
.OnAction = "DiagrammBild_löschen"
.Border.Weight = xlMedium
End With
Application.ScreenUpdating = True
End Sub
Sub DiagrammBild_löschen()
Bild.Delete
Set Bild = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

Lucky-Striker · 24. Oktober 2008

Hi EarlFred,

also nur PIC kommt gar nicht so gut, aber die vorherige Variante ist jetzt spitze!
Herzlichen Dank für Deine Hilfe!

PS: Das Bild wurde bei Aufruf übrigens immer unscharf dargestellt. Dafür zeichnet sich wohl dieser Parameter (oder wie auch immer man das bezeichnet! *Smilie ) verantwortlich:

Me.PictureSizeMode = fmPictureSizeModeZoom

Ich habe rumgespielt und seit ich

Me.PictureSizeMode = fmPictureSizeModeClip

benutze, funktioniert es einwandfrei!

Nochmals, herzlichen Dank und nice Weekend

Timo

User · 1. März 2011

Hallo.

Wollte das oben beschriebene mal auspropieren, aber ich bekomme es einfach nicht hin.

Habe das Diagramm in einem separaten Chart Blatt und möchte in einem Tabellenblatt innerhalb dieser Arbeitsmappe am Besten das Diagramm als kleines eingebettetes Bild haben. Und wenn ich dieses kleine Diagramm Bild anklicke soll sich das Diagramm in einem Pop Up Fenster in einer entsprechenden Größe öffnen.

Ich weiß leider nicht an welcher Stelle ich Eure oben beschriebenen Codes einfügen soll??

Vieleicht könnt ihr mir ja noch einmal helfen.

MFG

Office: (Office 2007) Diagramm als separates Popup öffnen

Diagramm als separates Popup öffnen

Diagramm als separates Popup öffnen

Diagramm als separates Popup öffnen

Diagramm als separates Popup öffnen

Diagramm als separates Popup öffnen - Similar Threads - Diagramm separates Popup

Diagramm excel - Achsenoptionen

Diagramm

Vereinfachtes Gantt-Diagramm mit Kalenderwochen und Jahren

Nullen in Diagramm nicht anzeigen

Diagramm als Vollbild?

XY-Diagramm-Grafik mit zusätzlichen Daten erweitern

Jedes Diagramm hat eigenen Verknüpfung