Office: Excel Formel

Hallo,
ich benötige Hilfe bei einer Formel:

Die Formel soll einen Wert wiedergeben, der teilweise fix ist teilweise in gewissen Bereichen (im Beispiel unten im Bereich von 150 -1090) schritthaft ansteigt. Für jeden Schritt von 70 soll der Wert um 12,9 erhöht werden. So weit so einfach. Mit folgender Einschränkung habe ich aber meine Probleme:
Wenn der Schritt bis zum Ende des Bereiches aber weniger als die Hälfte beträgt, soll der Wert nicht erhöht werden.
Wie Kann ich das in die Formel integrieren?

Die Formel sieht so aus:
=WENN(UND(0<=E4;E4<=150);34,1;
WENN(UND(150<E4;E4<=1090);(AUFRUNDEN(((E4-150)/70);0)*12,9)+34,1;[...]

In Schritten würde das bedeuten:
150,00 34,10
220,00 47,00
290,00 59,90
360,00 72,80
430,00 85,70
500,00 98,60
570,00 111,50
640,00 124,40
710,00 137,30
780,00 150,20
850,00 163,10
920,00 176,00
990,00 188,90
1.060,00 201,80
1.090,00 214,70 richtig wäre hier statt 214,70 jedoch 201,80, da die Steigerung nur 30 beträgt und 30 weniger als die Hälfte von 70 ist.

Jetzt könnte man einen neuen Bereich definieren (1060-1090) und in der Formel einfach 201,80 als Ergebnis auswerfen. Da die Formel aber noch weit mehr Bereiche hat als hier dargestellt, wär das ein enormer Aufwand.

Kann mir da jemand helfen?

lg Alex

 

F4: =KÜRZEN(RUNDEN((E4-150)/70;3))*12,9+34,1

Das RUNDEN ist nur zur Vermeidung von Gleitkommaberechnungsfehlern da.

Das Problem ist nicht erschöpfend dargestellt! Daher musste ich raten, was Du im Bereich oberhalb 1000 genau willst.

 

Danke für die Antwort.

Mit deinem Löscungsvorschlag komme ich bei 1090 auf den wert 207,32. Bei 1090 sollte aber der gleiche Wert wie bei 1060 rauskommen (also 201,80).

Der nächste Bereich ist dann von 1090 bis 2180. Hier soll für jeden Schritt von 180 der Wert um 22,30 erhöht werden. Hier gibt es wieder einen kleinen Sprung (also einen Sprung der weniger als die Hälfte von 180 beträgt) von 2170 bis 2180, der nur 10 beträgt. Hier soll der Wert nach obiger Vorgabe nicht erhöht werden.

 

Meine Formel #1 war korrekt! Es kam bei 1090 ebenfalls 201,8 raus. Was ich nicht beachtet habe, ist "die Hälfte von 70 bzw 180", was man mit RUNDEN statt KÜRZEN hinbekommt.

Ab XL2021 folgende Erweiterung zu #2:

F4: =LET(a;E4;x;VERGLEICH(a;{0.150.1090});
MAX(34,1;KÜRZEN((a-INDEX({0.150.1090};x))/INDEX({1.70.180};x))*INDEX({0.12,9.22,3};x)+INDEX({0.34,1.201,8};x)))

Für älteres Excel (kennt LET nicht):

F4: =MAX(34,1;KÜRZEN((E4-
INDEX({0.150.1090};VERGLEICH(E4;{0.150.1090})))/
INDEX({1.70.180};VERGLEICH(E4;{0.150.1090})))*
INDEX({0.12,9.22,3};VERGLEICH(E4;{0.150.1090}))+
INDEX({0.34,1.201,8};VERGLEICH(E4;{0.150.1090})))