Office: Excel mit VBA ganze Zeile nach einem Wert in Zelle löschen

Hallo zusammen
Mein Kopf ist kurz vorm Explodieren. Hoffe auf eure Hilfe:
Ich versuche mit einem Makro anhand des Wertes der in Zelle G1 steht, alle Zeilen mit diesem Wert in der Tabelle zu löschen.
Zuerst habe ich es mit Filtern versucht:
Sheets("Offene Zahlungen Arbeiten").Select
ActiveSheet.ListObjects("Tabelle7").Range.AutoFilter Field:=1, Criteria1:=Range("G1").Value
Range("A2:A5").SpecialCells(xlCellTypeVisible).EntireRow.Delete
ActiveSheet.ListObjects("Tabelle7").Range.AutoFilter Field:=1

Da war das Problem, dass sich die Tabelle laufend verändert durch Einträge und Löschungen. Also Range("A2:A5") stimmt dann nicht mehr und habe nichts im Netz gefunden als Lösung.

Dann habe ich es mit diesem Code ohne Filtern versucht (Im Netz gefunden und kopiert):
Sheets("Offene Zahlungen Arbeiten").Select
lz = Cells(Rows.Count, 1).End(xlUp).Rows.Row
For t = lz To 2 Step -1
If Cells(t, 1).Value = ("G1") Then
Rows(t).Delete Shift:=xlUp

End If
Next t
Das hat einmal funktioniert aber jetzt passiert gar nichts mehr.
Ich bin sicher ihr seht den Fehler sofort, habe wenig Erfahrung mit VBA und finde trotz intensiver suche nichts im Netz. Falls ihr eine Beispieldatei braucht kann ich die auf Wunsch erstellen und hochladen.
Gruss Jürg

 

Moin,
versuche mal

Code:

Option Explicit
Private Sub Loeschen()
 Dim Zeile As Long
    Sheets("Offene Zahlungen Arbeiten").Select
    For Zeile = 2 To Sheets(1).UsedRange.SpecialCells(xlCellTypeLastCell).Row
        If Cells(Zeile, 1) = Cells(1, 7) Then Rows(Zeile).Delete Shift:=xlUp
    Next Zeile
End Sub

Gruß
Doming

 

Danke dir, funktioniert gut..

 

Hi,

das geht auch ohne Schleife über alle Zeilen, denn die Intelligente Tabelle ist ein Objekt im Tabellenblatt, welches man direkt ansprechen kann:

Code:

Sub ZeilenLoeschen()
    With Worksheets("Offene Zahlungen Arbeiten")
        .ListObjects(1).Range.AutoFilter Field:=1, Criteria1:=.Range("G1")
        .ListObjects(1).DataBodyRange.Columns(1).SpecialCells(xlCellTypeVisible).Delete
        .ListObjects(1).Range.AutoFilter Field:=1
    End With
End Sub

Außerdem: das Tabellenblatt muss dazu nicht erst selektiert/aktiviert werden - mit eine With-Anweisung kann man sich direkt darauf beziehen. Beachte dabei, dass vor jedem innerhalb der Anweisung angesprochenen Objekt (im Beispiel Zelle, ListObject) ein Punkt . stehen muss, um Excel deren Zugehörigkeit zum übergeordneten Objekt mitzuteilen.

---

 

Hallo Beverly,
hätte man das dann nicht auch so schreiben können?

Code:

Sub ZeilenLoeschen()
   With Worksheets("Offene Zahlungen Arbeiten").ListObjects(1)
       .Range.AutoFilter Field:=1, Criteria1:=.Range("G1")
       .DataBodyRange.Columns(1).SpecialCells(xlCellTypeVisible).Delete
       .Range.AutoFilter Field:=1
   End With
End Sub

 

Hi,

hast du deinen Code mal getestet? Es hat schon seinen Grund, weshalb ich ihn NICHT so geschrieben habe.

---

 

Hallo Beverly
Diesen Code versteh ich sogar besser. Funktioniert super. Danke für deine Hilfe.
Noch eine Frage die ähnlich ist und ich deshalb nicht xtra ein neues Thema öffnen möchte:
Ich habe für eine Kundenerfassung per VBA (Makro) bei einer Änderung der bestehenden Daten wie z.B. Adressänderung einen Code der mit der bestehenden Kundennummer und Namen alles in eine neue Zeile kopiert und dann die doppelten löscht.
ActiveSheet.ListObjects("Kundenkartei").DataBodyRange.RemoveDuplicates Columns:=Array(1, 2), _
Header:=xlYes
Das Problem ist aber jetzt, es löscht mir den neuen und nicht den älteren Eintrag. Gibt es ein Code um den älteren Eintrag zu löschen? Der neue ist ja immer auf Zeile 2, Vielleicht kann man damit etwas machen?
Zur Info: Ich muss es mit einer neuen Zeile lösen. Der Grund dafür wäre aber zu Umfangreich zu erklären. (Mehrere Szenarien mit dem gleichen Makro verbunden)

 

Hi,

du könntest dieses Problem komplett umgehen, wenn du zuerst die Zeile mit den alten Daten löschst und danach die neuen überträgst.

---

 

Stimmt, daran hatte ich auch schon gedacht. Nur da ich das Makro auch für neue Kunden verwende findet es dann nichts zum löschen, da es diese Kundenummer noch nicht gibt. Da müsste ich mit if.. Arbeiten aber dafür reichen meine VBA Kenntnisse (noch) nicht.

 

Vom Prinzip her also so:

Code:

Sub SuchenLoeschen()
    Dim rngSuche As Range
    With Worksheets(1).ListObjects(1).DataBodyRange
        ' in der 1. Spalte der Tabelle nach der Zahl 10 suchen, dabei komplette Übereinstimmung erforderlich
        Set rngSuche = .Columns(1).Find(10, lookat:=xlWhole)
        ' Suchbegriff wurde gefunden dann Zeile löschen
        If Not rngSuche Is Nothing Then rngSuche.EntireRow.Delete

        ' hier dann dein Code zum Kopieren       

    End With
End Sub

---

 

Herzlichen Dank Beverly, es passt Perfekt. Jetzt kann ich das Programm endlich fertig stellen.
Lieber Gruss
Jürg