Office: Exponent

Lenny · 18. März 2006

Servus zusammen!

Eigentlich bin ich mit meinem Problem hier im falschen Forum, da es im Grunde nicht um EXCEL/VBA geht, aber ich wusste in meiner Not nicht, wohin sonst... Und es gab gute Gründe hierher zu kommen: es handelt sich um ein grundsätzliches Programmier-Problem, das man durchaus auch mit VBA behandlen kann und außerdem gibt es hier viele schlaue Leute!
Aber zum Problem! Ich brauche folgende Funktion:

Eingabe: Zahl A, Zahl B
Ausgabe: A^B, also "A hoch B"
Der Haken: Es dürfen nur die Grundrechenarten +-*/ verwendet werden!
Hintergrund: Ich brauch ein Programm in einer anderen Programmiersprache (zu der ich kein Forum kenne), und in dieser Sprache gibt es keinen Exponenten. Würde mir gerne so eine Funktion schreiben.

Kennt jemand eine geeignete Schleife, die sowas berechnen kann? Oder eine Mathe- / Programmierseite, wo man sowas finden kann?

Herzlichsten Dank!
Und es wäre nett, wenn ihr diesen Beitrag nicht aus dem Forum schmeißt! Weil wie gesagt, eigentlich falscher Ort, aber für einen VBA-Profi vielleicht ja auch eine nette Herausforderung!

:)

User · 20. März 2006

Hi Lenny,

versuche es mal mit diesem VBA-Code (wenn ich dich richtig verstanden habe)
Code:

Sub exponent()
Dim doB As Double
Dim doA As Double
Dim doErgebnis As Double
doErgebnis = 1
doA = 2
For doB = 1 To 4
doErgebnis = doErgebnis * doA
Next doB
Cells(1, 1) = doErgebnis
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

[Edit]: Ausgangswert für doErgebnis im Code geändert

jinx · 20. März 2006

Moin, Karin,

2^4 ist 16, nicht 32: doErgebnis sollte auf 1 gesetzt werden.

Lenny · 20. März 2006

Tach Beverly & jinx!

Danke für die schnelle Antwort!
OK, für ganzzahlige Exponenten funktioniert das ganz schön!
Nur: was mache ich bei negativen Exponenten? Oder bei gebrochenen Exponenten? For I = 1 to 1,333 macht wenig Sinn*Smilie
Ich weiß: damit dürfte die Sache um einiges anspruchsvoller werden...
Hoffe, es gibt trotzdem jemanden, der das schafft!

M@x · 20. März 2006

Hi
Dann fällt mir nur das gute alte Logarithmenmrechnen ein
in Excel würd das dann so ausschauen:
=EXP(LN(A1)*B1)
aber diese Funktionen stehn dir dann wahrscheinlich auch nicht zur Verfügung

Lenny · 20. März 2006

Hi Max,

die Idee hatte ich auch schon, aber wie du richtig vermutet hast, gibt es auch keine ln- oder log-Funktionen...
Trotzdem Danke!
Weitere Ideen?

Unimatrix Zero · 21. März 2006

Moin Lenny,

habe mal ein bischen rumgespielt *wink.gif* .
Es gibt allerdings noch ein paar Einschränkungen bei meinem Lösungsvorschlag:
Es existiert (noch) keine Fehlerabfangroutine für einen Zahlen-Überlauf,
Der Startwert bei der Iteration für rationale Exponenten muß sogfältig ausgewählt werden, da man sonst auch schnell in einen Überlauf kommt (nachdem ich schon eine Weile aus der Schule heraus bin und auch kein Mathematiker bin ist mir auf die Schnelle jetzt nichts eingefallen, wie man den Startwert möglichst einfach abschätzen könnte),
Komplexe Ergebnisse wurden nicht berücksichtigt.
Code:

Private Function Modulo(ByVal z, ByVal n) As Long
'Rest aus Division ermitteln
Dim i&

Do While z / n < 1
z = z * 10
Loop

i = CLng(z / n)
Modulo = z - (i * n)

End Function

Private Function ggT(ByVal a, ByVal b)
'größten gemeinsamen Teiler ermitteln

Dim i

Do While a > 0
i = a
a = Modulo(b, a) 'a = b Mod a
b = i
Loop

ggT = b

End Function

Private Function NatPot(ByVal x, ByVal y)
'Potenz ermitteln mit natürlichem Exponent y

Dim i, j

j = 1

For i = 1 To y
j = j * x
Next

NatPot = j

End Function

Private Function RatPot(ByVal x, ByVal y)
'Potenz ermitteln mit rationalem Exponent y

Const GENAUIGKEIT = 0.00001 'Genauigkeit des Ergebnisses festlegen
Dim a, b, z, n, s, e, r, t

'y in einen Bruch umwandeln
a = Abs(y)
b = 1

Do
b = b * 10
a = a * 10
Loop Until Int(a) = a

t = ggT(a, b) 'größten gemeinsamen Teiler (ggT) ermitteln um Überlauf hinauszuzögern
a = a / t
b = b / t
s = 100 'Startwert festlegen
If y > 0 Then r = NatPot(x, a) Else r = 1 / NatPot(x, a)

Do
e = s
z = ((b - 1) * NatPot(s, b)) + r
n = b * NatPot(s, b - 1)
s = z / n
Loop Until Abs(e - s) < GENAUIGKEIT

RatPot = Round(s, 4)

End Function

Public Function Potenz(ByVal x, ByVal y)

'Sonderfälle für Basis x
Select Case x
Case 0
If y = 0 Then
Potenz = "nicht definiert"
Else
Potenz = 0
End If
Exit Function
Case 1
Potenz = 1
Exit Function
End Select

'Feststellen welche Art von Exponent y vorliegt
Select Case y
Case 0
Potenz = 1
Exit Function
Case 1
Potenz = x
Exit Function
Case Is > 0

If Int(y) = y Then 'natürlicher Exponent
Potenz = NatPot(x, y)
Else 'rationaler Exponent

Select Case x
Case Is < 0
Potenz = "komplexe Zahl"
Case Else
Potenz = RatPot(x, y)
End Select

End If

Case Is < 0

If Int(y) = y Then 'ganzzahliger negativer Exponent
Potenz = 1 / NatPot(x, y * -1)
Else 'rationaler negativer Exponent

Select Case x
Case Is < 0
Potenz = "komplexe Zahl"
Case Else
Potenz = RatPot(x, y)
End Select

End If

End Select

End Function

Sub PotBsp()
Debug.Print CStr(Potenz(0, 0)) 'Ergebnis = nicht definiert
Debug.Print CStr(Potenz(3, 4)) 'Ergebnis = 0,4665
Debug.Print CStr(Potenz(6, -3)) 'Ergebnis = 0,004629629
Debug.Print CStr(Potenz(3, 1.34)) 'Ergebnis = 4,3586
Debug.Print CStr(Potenz(2, -1.1)) 'Ergebnis = 0,4665
Debug.Print CStr(Potenz(-3, 2)) 'Ergebnis = 9
Debug.Print CStr(Potenz(-4, -3)) 'Ergebnis = -0,015625
Debug.Print CStr(Potenz(-3, 1.2)) 'Ergebnis = komplexe Zahl
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Lenny · 21. März 2006

Tach Dieter,

Dankeschön!!!
Ich muss sagen, für einen Nicht-Mathematiker ganz ordentlich *wink.gif*
Bin noch nicht dazu gekommen, das ganze zeilenweise nachzuvollziehen, aber es sieht auf Anhieb schon so aus, als passt das!!!

Merci nochmal!

Office: Exponent

Exponent

Exponent

Exponent

Exponent

Exponent - Similar Threads - Exponent

Datenimport HTML-Datei fehlerhaft (führende Null + Exponent)