Office: (Office 2007) Funktion mit mehreren Rückgabewerten

dhartung · 18. Januar 2011

Hallo zusammen,

Ich bekomme es nicht hin das ich eine Funktion in VBA mehrere werte zurück gibt.

Mehrere Werte aus einer Sub in die Funktion senden um ein Rückgabewert zu erhalten ist kein Problem. (z.B. X=2; Y=3 --> Funktion rechnet 2*3 = 6 und gibt mir die 6 wieder in die Sub zurück.

Doch wie stelle ich es an das ich von der Funktion auch 2+3 und 3-2 und 3/2 erhalte und das icn 4 verschiedene Variablen leich in der Sub weiterverarbeiten kann?

:)

Erich G. · 19. Januar 2011

Hi Daniel,
schau dir mal diese Codes an:
Code:

Option Explicit

Sub A_Aufgaben()
Dim xx As Double, yy As Double
Dim dblSum As Double, dblDif As Double, dblQuo As Double

xx = 3
yy = 7
MsgBox A_ProdUa(xx, yy, dblSum, dblDif, dblQuo)
MsgBox dblDif
End Sub

Function A_ProdUa(dblA As Double, dblB As Double, _
dblES As Double, dblED As Double, dblEQ As Double) As Double
A_ProdUa = dblA * dblB
dblES = dblA + dblB
dblED = dblA - dblB
dblEQ = dblA / dblB
End Function

Sub B_Aufgaben()
Dim xx As Double, yy As Double
Dim dblPro As Double, dblSum As Double, dblDif As Double, dblQuo As Double

xx = 3
yy = 7
B_ProdUa xx, yy, dblPro, dblSum, dblDif, dblQuo
MsgBox dblPro
MsgBox dblDif
End Sub

Sub B_ProdUa(dblA As Double, dblB As Double, _
dblEP As Double, dblES As Double, dblED As Double, dblEQ As Double)
dblEP = dblA * dblB
dblES = dblA + dblB
dblED = dblA - dblB
dblEQ = dblA / dblB
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Auch eine Fkt. kann Parameter zurückgeben - nicht nur den Funktionswert.

Aber geschickter ist hier wohl eine Sub - alle Parameter werden dann gleich behandelt.
Alles klar?

EarlFred · 19. Januar 2011

Hallo Daniel,

meinst Du sowas?

Code:

Sub aufruf()
Dim Ergebnisse As Variant

Ergebnisse = Berechne(2, 3, 9, 12)

End Sub

Function Berechne(ByVal i As Double, _
ByVal j As Double, _
ByVal k As Double, _
ByVal l As Double) As Variant

Berechne = Array(i * j, k + l, i - l, j / k)

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

josef e · 19. Januar 2011

Hallo ?,

wozu das gut ist, mussich ja nicht verstehen;-))

Function wiredNumbers(ByVal Num1 As Double, ByVal Num2 As Double) As Variant
Dim dblTmp(3) As Double

dblTmp(0) = Num1 + Num2
dblTmp(1) = Num1 - Num2
dblTmp(2) = Num1 * Num2
dblTmp(3) = Num1 / Num2

wiredNumbers = dblTmp
End Function

Sub test()
Dim vntRet() As Double

vntRet = wiredNumbers(2, 3)

MsgBox vntRet(0) & vbLf & vntRet(1) & vbLf & vntRet(2) & vbLf & vntRet(3)

End Sub

Gruß Sepp

dhartung · 20. Januar 2011

Hallo alle zusammen,

Die Lösung vom Josef hat mir am besten gefallen da sie einfach zu verstehen war und kurz und knackig ist.

1000 dank für die anderen Lösungen. Es hilft unheimlich VBA besser zu verstehen um so andere Herrausforderungn zu lösen.

- für was ich es brauche.....

Ich bin dabei ein Makro zu schreigen das mehrere 100 Word files nach bestimmten Zeichenstätze durchsucht und Kategorisiert. Eure Hilfe brauchte ich um eine Funktion zu schreiben die 4 Werte zurückgibt und ich dann in die entsprechenden Zellen schreibe.

Office: (Office 2007) Funktion mit mehreren Rückgabewerten

Funktion mit mehreren Rückgabewerten

Funktion mit mehreren Rückgabewerten

Funktion mit mehreren Rückgabewerten

Funktion mit mehreren Rückgabewerten - Similar Threads - Funktion mehreren Rückgabewerten

WENN-Funktion mit mehreren Bedingungen

Formelbezug auf noch nicht existierende Blätter

WENN UND Funktion mit mehreren Bedingungen (Sozialversicherungsgrenzen)

Funktion von Summenprodukten aus mehreren Matrizen verkürzen

Anfänger - Hilfe Excel WENN Funktionen

Mehrere WENN Funktion für Textilien

WENNS Funktion mit mehreren Bedingungen