Office: im Serienbrief tabellenzeile ausblenden

Hallo,

kann man im Serienbrief Tabellenzeilen ausblenden wenn diese leer sind?

Sprich muss in manchen Rechnungen benötige ich mehr Rechnungszeilen. Diese Zeilen sollen aber nicht leer bei den anderen Rechnungen auftauchen.

 

Hi,

Du hast ja jetzt einige Fragen zu Serienbriefe gestellt. Vielleicht schaust du Dir mal diese Seite an:

http://mypage.bluewin.ch/reprobst/FrmSet.htm?MMInhalt

Dort kannst du mal ein bischen stöbern udn findest bestimmt die eine oder andere Antwort. Oder vielleicht sogar neu Ideen für Lösungen...

Aber noch was zu diesen Geschichten:
Du kannst diese Sachen alles in dein mdb machen. Wenn Du Access als Datenquelle hast, kannst du dort eine Abfrage erstellen und alle Bedingungen angeben - dann kommen die Daten auch entsprechend gefiltert in Word an.

Du kannst aber auch in Word mit VBA die Verbindung zur Datenquelle herstellen und dann mit einem SQL-String arbeiten...

PS: auch hier kannst du ggf. etwas zu Serieenbreifen und Feldern in Word finden:
http://www.Wordwelt.de

 

Hallo,
kann man im Serienbrief ganze Tabellenzeilen ausblenden wenn diese leer sind?

 

Hallo ,

in einem Word-Serienbrief werden Absätze, in denen Seriendruckfelder stehen, die einen Leerstring ergeben, automatisch ausgeblendet. Tabellenzeilen können aber nicht automatisch ausgeblendet werden.

Das bedeutet für dich: Entweder auf Tabellen verzichten und nur mit Absätzen arbeiten, oder die resultierenden Tabellen nachträglich bearbeiten, evtl. unter Einsatz von VBA.

Näheres kann man vielleicht sagen, wenn du mehr Infos lieferst:

• Die Tabellenzeilen sind leer, weil in ihnen nichts steht?
• Oder sie sind leer, weil die Seriendruckfelder in den Zeilen leer ergeben?
• Handelt es sich um eine einspaltige oder mehrspaltige Tabelle?
• Ein oder mehrere Seriendruckfelder pro Zelle /Zeile?

Am besten lädst du ein Muster deines Seriendruck-Hauptdokuments hoch, dann kann man was überlegen.

 

Hallo Gerhard,

Danke vorab mal für deine rasche Rückmeldung!
1.Es sollten die zwei Zeilen die Gelb markiert sind, dann ausgeblendet werden wenn keine Mwst. drinnen steht.
2.Beim Feld HR Nr. das Feld das Rot markiert ist, sollte 44/2 stehen, es wird allerdings 0 angezeigt.
Vielleicht lässt sich da was machen!
Danke schon im Voraus.
Habe die Dateien hochgeladen.

LG. RZ1973

 

Das rote Feld wird bei mir korrekt übertragen, kann aber damit zusammenhängen, dass bei dir das als Bruch gedeutet wird. Würde ich in Excel lösen indem ich das in einer Hilfszelle mit der =TEXT()-Funktion in echten Text umwandle.
Aber, die entscheidende Frage: warum wird denn bei der Rechnung die MWSt einmal ausgewiesen und einmal nicht?

Ansonsten kannst du mal das hier versuchen.
Zuerst gehst du im SB auf die Funktion "Fertigstellen und Zusammenführen/Einzelne Dokumente bearbeiten", da bekommst du dann für jeden Datensatz ein eigenes Dokument.
Das muss das aktive sein, dann kannst du dieses Makro hier mal ausprobieren:

PHP:

Sub zeilenWeg()
Dim dd1 As Document: Set dd1 = ActiveDocument
Dim tab01 As Table, i As Long
Dim strA As String
 For i = 1 To dd1.Tables.Count
 Set tab01 = dd1.Tables(i)
   If InStr(tab01.Cell(5, 4).Range.Text, "Nettoentgelt") = 0 Then
    tab01.Rows(6).Delete
    tab01.Rows(5).Delete
   End If
 Next i
End Sub


 

Auch bei mir wird das rote Feld korrekt übertragen. Vielleicht hilft es auch, die Mappe, die ja im Kompatibilitätsmodus läuft, zu konvertieren (Datei > Informationen). Das soll ja manchmal Wunder wirken.

 

Hallo Gerhard,
Die Datei habe ich konvertiert, hat alleine nichts genutzt. Doch wenn die ganze Spalte Hausnummer mit dem Format "Text" formatiert ist, funktioniert es perfekt. Es klappt auch wenn der 1. Eintrag auf " Text" und der Rest mit "Standart" formatiert ist, würde es auch klappen. Also habe ich alles auf "Text" formatiert und nun ist alles Bestens!

Danke für deine Bemühungen!

LG

 

Hallo Czil,

Ich habe dein Makro probiert, es funktioniert soweit schon.
Nur in Verbindung mit meinem Makro, das ich die Rechnungen als pdf abspeichere bekomme ich nicht hin.
Man müsste vielleicht deine Makrozeilen in mein Makro integrieren.
Das schaffe ich allerdings nicht.
Also werde ich damit leben müssen, das die leeren Zeilen stehen bleiben.

Danke für deine Bemühungen!

LG

 

Hallo RZ,

ich hege durchaus Hoffnung, dass man czils Makro in deines intgrieren kann. Gewissheit könnte daraus werden, wenn du es mal herzeigst.

 

OK, das ist dann ja eine ganz andere Voraussetzung. Denn du kannst im SBDokument nichts ausblenden was dann nicht auf alle Dokumente durchschlägt. Das geht nur in der Einzeldokumentbearbetung.
Da die Pdf-Speicherdinger aber im Regelfall diese nutzen, muss man das halt da in den Code mit einbauen. Das ist nur die Frage der richtigen Stelle.
Hier hat es Gerhard schon gesagt: her mit dem Makro, dann geht das einfacher zu beurteilen.
(Btw, verstehe ich den Grund für ein Makro zum speichern als pdf nicht so ganz, aber das scheint ein beliebtes Hobby zu sein)

 

Hallo Gerhard, Hallo czil,

Das wäre das Makro.
LG

Option Explicit

Sub PDFSpeichern()
'
' PDFSpeichern Makro
'
'
'
'
' set variables
Dim iBrief As Integer, sBrief As String
Dim AppShell As Object
Dim BrowseDir As Variant
Dim Path As String
' catch any errors
On Error GoTo ErrorHandling

' determine path
Set AppShell = CreateObject("Shell.Application")
Set BrowseDir = AppShell.BrowseForFolder(0, "Speicherort für Serienbriefe auswählen", 0, 16)

If BrowseDir = "Desktop" Then
Path = CreateObject("WScript.Shell").SpecialFolders("Desktop")
Else
Path = BrowseDir.items().Item().Path
End If

If Path = "" Then GoTo ErrorHandling

Path = Path & "\WG Rechnungen-" & Format(Now, "dd.mm.yyyy-hh.mm.ss") & "\"
MkDir Path


On Error GoTo ErrorHandling

' hide application for better performance
MsgBox "Serienbriefe werden exportiert. Dieser Vorganag kann einige Minuten dauern - Microsoft Word wird während dieser Zeit ausgeblendet", vbOKOnly + vbInformation
Application.Visible = False

' create bulkletter and export as pdf
With ActiveDocument.MailMerge
.DataSource.ActiveRecord = 1
Do
.Destination = wdSendToNewDocument
.SuppressBlankLines = True
With .DataSource
.FirstRecord = .ActiveRecord
.LastRecord = .ActiveRecord

sBrief = Path & .DataFields("Name").Value & "_Re.Nr." & .DataFields("RE").Value & Format("_2024") & ".pdf"
End With
.Execute Pause:=False

If .DataSource.DataFields("Name").Value > "" Then
ActiveDocument.SaveAs FileName:=sBrief, FileFormat:=wdFormatPDF
End If
ActiveDocument.Close False

If .DataSource.ActiveRecord < .DataSource.RecordCount Then
.DataSource.ActiveRecord = wdNextRecord
Else
Exit Do
End If
Loop
End With

' error handling
ErrorHandling:
Application.Visible = True

If Err.Number = 76 Then
MsgBox "Der ausgewählte Speicherort ist ungültig", vbOKOnly + vbCritical
ElseIf Err.Number = 5852 Then
MsgBox "Das Dokument ist kein Serienbrief"
ElseIf Err.Number = 4198 Then
MsgBox "Der ausgewählte Speicherort ist ungültig", vbOKOnly + vbCritical
ElseIf Err.Number = 91 Then
MsgBox "Exportieren von Serienbriefen abgebrochen", vbOKOnly + vbExclamation
ElseIf Err.Number > 0 Then
MsgBox "Unbekannter Fehler: " & Err.Number & " - Bitte Makro erneut ausführen.", vbOKOnly + vbCritical
Else
MsgBox "Serienbriefe erfolgreich exportiert", vbOKOnly + vbInformation
End If

End Sub

 

Hallo RZ,

hier ein Vorschlag zur Integration beider Makros:

Code:

Sub PDFSpeichern()

' set variables
Dim hauptDoc As Document, tempDoc As Document
Dim anzahlDS As Long, i As Long
Dim BasisPfad As String, path As String, sBrief As String


' catch any errors
On Error GoTo ErrorHandling

Set hauptDoc = ThisDocument 'das ist dein Seriendruck-Hauptdokument

' determine path
BasisPfad = "C:\1temp\rz1973\" '<--*****Anpassen
path = BasisPfad & "WG Rechnungen-" & Format(Now, "dd.mm.yyyy-hh.mm.ss") & "\"
MkDir path
' hide application for better performance
'MsgBox "Serienbriefe werden exportiert. Dieser Vorganag kann einige Minuten dauern - Microsoft Word wird während dieser Zeit ausgeblendet", vbOKOnly + vbInformation
'Application.Visible = False

    ' create bulkletter and export as pdf
    With ThisDocument.MailMerge
 
      'erst mal schauen, ob das Dokument mit der Datenquelle verknüpft ist:
      If .MainDocumentType = wdNotAMergeDocument Then
           MsgBox "Das Dokument ist noch nicht mit einer Seriendruckquelle verbunden."
           Exit Sub
        End If

        'Prüfen, ob Datensätze vorhanden sind:
        .DataSource.ActiveRecord = wdLastDataSourceRecord
        anzahlDS = .DataSource.ActiveRecord
            If anzahlDS = 0 Then
                MsgBox "Es wurden keine Datensätze gefunden."
                Exit Sub
            End If
       
        'pro Datensatz 1 PDF erzeugen:
        .DataSource.ActiveRecord = 1
        .Destination = wdSendToNewDocument
       
            For i = 1 To anzahlDS
                .DataSource.ActiveRecord = i
           
                 .DataSource.FirstRecord = i
                .DataSource.LastRecord = i
                .Execute
                Set tempDoc = ActiveDocument
                                           
                'im temporären Dokument leere Tabellenzeilen löschen:
                Call bereinige(tempDoc)
                                                                       
                'Dokument unter dem gewünschten Namen als PDF speichern und tempDoc löschen:
                sBrief = path & .DataSource.DataFields("Name").Value & "_Re.Nr." & _
                .DataSource.DataFields("RE").Value & "_2024.pdf"
                MsgBox sBrief
                tempDoc.ExportAsFixedFormat outputfilename:=sBrief, exportformat:=wdExportFormatPDF
                tempDoc.Close savechanges:=False
            Next i
        End With
Exit Sub

ErrorHandling:
Application.Visible = True
MsgBox Err.Number & Err.Description
End Sub

Sub bereinige(dd1)
Dim tab01 As Table

Set tab01 = dd1.Tables(1)
    If InStr(tab01.Cell(5, 4).Range.Text, "Nettoentgelt") = 0 Then
        tab01.Rows(6).Delete
        tab01.Rows(5).Delete
    End If
End Sub

Hinweise:

• Da ich das Gehubere mit BrowseDir etc nicht mag, und es auch merkwürdig finde, dass die Erfolgsmeldung im Errorhandling erscheint, hab ich, was das Speichern der Dokumente als PDF betrifft, meinen eigenen Stiefel geritten.
• Die noch nötigen Überreste von czils Makro finden sich in der Sub bereinigen().
• Es wird davon ausgegangen, dass es pro Adressat (= pro erzeugten PDF) nur 1 Tabelle gibt, deren Struktur dem Musterdokument entspricht.
• Die Meldung wg Ausblenden des Hauptdokuments hab ich auskommentiert, weil ich während der Testphase gern zusehe, was passiert. Kannst ja später wieder aktivieren.
• Die beiden Makros müssen im Zum Testen die Makros im Hauptdokument aus Beitrag #5 untergebracht werden.

 

Hallo Gerhard,

Ich bekomme immer die Fehlermeldung:
"Das Dokument ist noch nicht mit einer Seriendruckquelle verbunden."
Die Daten kommen aber richtig in den Serienbrief.

Was kann es da haben? Mache ich da womöglich was falsch?

LG. RZ

 

Hallo RZ,

da ist erstens ein Fehler von mir: ich hab oben definiert:
Set hauptDoc = ThisDocument,

dann sollte weiter unten auch stehen:
With hauptDoc.MailMerge (statt with ThisDocument.Mailmerge). Dieser Fehler sollte allerdings folgenlos bleiben, da ja hauptDoc und ThisDocument aufs gleiche Dokument verweisen, es sei denn...

...das zweitens das Makro nicht im Seriendruck-Hauptdokument untergebracht ist, sondern sonstwo (vielleicht in deiner Normal.dotm?. Dann würde ThisDocument auf dieses Dokument verweisen, was ja tatsächlich keine Seriendruck-Hauptdokument wäre.

Was anderes fällt mir grad nicht ein. Ich häng dir mal das Dokument mit dem Makro drin an (gezippt, da hier Dokumente mit Makros nicht erlaubt sind). Es produziert bei mir diesen Fehler nicht.