Office: (Office 2010) Mehrere Tabellenblätter in ein PDF drucken wenn bedingung erfüllt

Hallo,

da ich mir nun seid mehreren Tagen darüber den Kopf zerbreche hab ich mir gedacht ich versuche es mal auf diesem wege.
Ich habe Folgendes Problem:
Ich würde gerne wie schon oben beschrieben ein PDF aus einer Excelmappe erstellen. Dieses soll aber nicht die Gesammte Mappe drucken, sondern nur bestimmt Seiten, zB welche die einen angegeben wert haben. Das direkte Drucken dieser Seiten habe ich auch hinbekommen.
Beispiel:

Code:

Sub Drucken()
If Sheets("Tabelle1").Range("A7") <> "" Then
Sheets("Tabelle2", "Tabelle3").PrintOut Copies:=1, Collate:=True
End If
End Sub

Für die PDF druck-Variante hab ich auch etwas gefunden:

Code:

Sub Drucken()
Dim pdfName As String

pdfName = Application.GetSaveAsFilename(Environ("USERPROFILE") & "\Desktop\" & "Test" & ".pdf", "PDF-Dateien (*.pdf), *.pdf")

Sheets(Array("Tabelle1", "Tabelle2")).Copy


With ActiveWorkbook
     .ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
                          Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
                          OpenAfterPublish:=True
     .Close savechanges:=False
End With
End Sub

Beide für sich Funktionieren so wie sie sollen. Ich bekomme nur nicht beide zusammen hin.

Ich hoffe einer von euch schlauen Köpfen kann mir hierbei weiterhelfen.
Vielen dank im vorraus.

Gruß Florian

 

Hi Florian,

meinst du so etwas:

Code:

Sub Drucken()
    Dim pdfName As String
    pdfName = Application.GetSaveAsFilename(Environ("USERPROFILE") & "\Desktop\" & "Test" & ".pdf", "PDF-Dateien (*.pdf), *.pdf")
    If Worksheets("Tabelle1").Range("A7") <> "" Then
        Worksheets(Array("Tabelle2", "Tabelle3")).Copy
        With ActiveWorkbook
             .ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
                Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
                OpenAfterPublish:=True
             .Close savechanges:=False
        End With
    End If
End Sub

Bis später,
Karin

 

Hi Karin,

vielen dank für die schnelle Antwort.
Sieht schon mal nach der richtigen richtung aus. Ich hab nur bei meinem Fall das Problem, dass ich eine riesege menge an Zellen habe wo etwas eingetragen werden kann und er bei 20 eingetragenen Werten mir die 20 Seiten die Damit zusammen hängen als ein PDF ausgeben soll. Plus zusätzlich ein Inhaltsverzeichnis, welches er immer ausdrucken müsste.

Gruß Florian

 

Hi Florian,

mit deiner Aussage kann ich leider nicht viel anfangen. Wie erkennt Excel denn, welche Tabellen wann ausgegeben werden sollen?

Bis später,
Karin

 

Hi Karin,

Es gibt eine Liste mit wo ich Längenangaben eingebe. Wenn eine Länge angegeben ist Soll er mit die Spezifische berechnung zu dieser länge ausgeben.

Das Bekomme ich ja über

Code:

Sub Drucken()
If Sheets("Tabelle1").Range("A1") <> "" Then
Sheets("Tabelle2", "Tabelle3").PrintOut Copies:=1, Collate:=True
End If
If Sheets("Tabelle1").Range("A2") <> "" Then
Sheets("Tabelle2", "Tabelle4").PrintOut Copies:=1, Collate:=True
End If
If Sheets("Tabelle1").Range("A3") <> "" Then
Sheets("Tabelle2", "Tabelle5").PrintOut Copies:=1, Collate:=True
End If
....
End Sub

hin. So hatte ich es bisher und konnte jede einzelne Zelle abfragen und wenn sie einen Wert hat einzen ausgeben. Problem Dabei ist nur das er mit dann 20 einzelne PDF Dokumente ausgibt und ich diese erst einzeln abspeichern müsste um sie dann nachher zusammen zu führen. Ich würde es daher für die spätere verwendung einfacher finden wenn er mir direkt nur 1 PDF ausgeben würde

Gruß Florian

 

Hi Florian,

verstehe ich das richtig, ausgehend von deinem Beispiel: es sollen Tabelle2 + Tabelle3 + Tabelle4 + Tabelle5 + Tabelle7 + Tabelle18 (wenn die betreffenden Zellen in Spalte A nicht leer sind) als ein gemeinsames PDF-Dokument erstellt werden? Tabelle2 soll in jedem Fall mit ausgegeben werden?

Bis später,
Karin

 

Hi Katrin,

ja so hab ich mir das vorgestellt.
Habe auch schon überlegt ob es nicht einfacher wäre es nicht als pdf zu speicher, sondern einfach eine neue Mappe zu eröffnen wo die betreffenden dann rein kopiert werden. Da müsste ich dann ja nur den prüfen ob ein Wert vorhanden und wenn ja dann die Tabelle kopieren.
Hänge aber bei der Idee in dem Punkt das ich nicht mehrere Sheets kopiert bekomme. Da ich ja vorher immer mit if-then abfragen muss ob die Zeile beschrieben ist.
Am ende Hätte ich dann eine Datei wo nur das drin wäre was auch zutreffend ist und die Kann ich dann einfach als PDF speichern.

Gruß Florian

 

Hi Florian,

der Code macht doch nichts anderes als eine neue Arbeitsmappe mit den betreffenden Tabellenblättern zu erstellen und diese dann als PDF abzuspeichern...

Du musst einfach nur alle relevanten Tabellenblätter in eine Array speichern und diese dann kopieren:

Code:

Sub PDFErstellen2()
    Dim lngZeile As Long
    Dim lngZaehler As Long
    Dim arrTabs()
    Dim pdfName As String
    ReDim arrTabs(0)
    arrTabs(0) = "Tabelle2"
    lngZaehler = 1
    With Worksheets("Tabelle1")
        For lngZeile = 1 To 20
            If .Cells(lngZeile, 1) <> "" Then
                ReDim Preserve arrTabs(0 To lngZaehler)
                arrTabs(lngZaehler) = "Tabelle" & lngZeile + 2
                lngZaehler = lngZaehler + 1
            End If
        Next lngZeile
        If UBound(arrTabs()) > 1 Then
            Worksheets(arrTabs).Copy
            pdfName = Application.GetSaveAsFilename(Environ("USERPROFILE") & "\Desktop\" & "Test" & ".pdf", "PDF-Dateien (*.pdf), *.pdf")
            With ActiveWorkbook
                 .ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
                    Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
                    OpenAfterPublish:=True
                 .Close savechanges:=False
            End With
        End If
    End With
End Sub

Bis später,
Karin

 

Hallo Karin,

ich hab mir gestern abend mal noch ein paar gedanken gemacht und habe es so gemacht, dass ich die betreffenden Seiten in eine Seperate Tabelle kopiere. SO ist es auch für die Spätere verwendung einfacher zu handhaben. Da hat sich aber jetzt ein neues problem ergeben. Da es jetzt aber nicht mehr unter den Fall "als PDF speichern" fällt, werde ich ein neues Thema aufmachen. Da es dieses mal um UnterSubs geht, da meine Datei zu groß wird und auch zu lang für ein VBA befehl.