Office: Mehrspaltige Listbox füllen

Venom · 19. Oktober 2010

Hi ich fülle eine Mehrspaltige Listbox anhand eines RecordSets mit folgendem Code
Code:

Set rs = db.OpenRecordset("Select * from tbl_Lager where Merkmal = 'Archiv' Order by Enummer Asc")
Do While Not rs.EOF
With Me.lst_RawDaten
.AddItem rs!Enummer
.List(ZeileFuerListbox, 1) = rs!EDatum
If IsNull(rs.Fields("ADatum")) Then
Else
.List(ZeileFuerListbox, 2) = rs!Adatum
End If
.List(ZeileFuerListbox, 3) = rs!LAgergut
.List(ZeileFuerListbox, 4) = rs!Anzahl
.List(ZeileFuerListbox, 5) = rs!Platzbedarf
.List(ZeileFuerListbox, 6) = rs!Gewicht
If IsNull(rs.Fields("Bemerkungen")) Then
Else
.List(ZeileFuerListbox, 7) = rs!Bemerkungen
End If
.List(ZeileFuerListbox, 8) = rs!Kundenobjekt
.List(ZeileFuerListbox, 9) = rs.Fields("Bereich/Team")
' .List(ZeileFuerListbox, 10) = rs!Auftraggeber
' .List(ZeileFuerListbox, 11) = rs!EUser
' .List(ZeileFuerListbox, 12) = rs!Transportfirma
' If IsNull(rs.Fields("AUser")) Then
' Else
' .List(ZeileFuerListbox, 13) = rs!Auser
' End If
ZeileFuerListbox = ZeileFuerListbox + 1
End With
rs.MoveNext
Loop
Set rs = Nothing
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wenn ich nun die in Spalte 10 einzufügenden Daten wieder einkommentiere bricht er mir ab mit FehlerCode 380 Eigenschaft.list kann nicht gesetzt werden.
Am FeldInhaltselber kann es nicht liegen. Ich habe es mal in eine andere Spalte schreiben lassen da geht es.

Gibt es ein maximum der zu nutzenden Spalten?

Im Eigenschaftsfenster der Listbox bei ColumnCount habe ich 14

Danke

Gruß
Venom

:)

Venom · 21. Oktober 2010

Wirklich keiner? :-(

EarlFred · 21. Oktober 2010

Hallo Venom,

Elemente einer Listbox mit Add und List gemischt zuzuweisen erscheint mir nicht optimal. Die List, die standardmäßig ohne Dimensionierung hinter dem Listenfeld steht, hat meines Wissens nur 10 Spalten, ich habe aber grad kein Excel zur Hand, um das zu testen.

Probier mal folgendes:
Erstelle ein Array, in das Du alle Elemente der Listbox einliest (eben 14 Spalten und x Zeilen, mit Redim Preserve arbeiten).

Wenn das Array vollständig ist, weise es der Listbox zu:
Listbox.List = Array.
Das sollte klappen.

Grüße
EarlFred

Venom · 21. Oktober 2010

Super
Danke das Teste ich morgen früh gleich an der Arbeit

gruß
Venom

EarlFred · 21. Oktober 2010

Hallo Venom,

so könnte es klappen:

Code:

Set rs = Db.OpenRecordset("Select * from tbl_Lager where Merkmal = 'Archiv' Order by Enummer Asc")
Dim arrList(0 To 13, 0 To rs.RecordCount - 1) As String

Do While Not rs.EOF
arrList(ZeileFuerListbox, 0) = rs!Enummer
arrList(ZeileFuerListbox, 1) = rs!EDatum
If Not IsNull(rs.Fields("ADatum")) Then
arrList(ZeileFuerListbox, 2) = rs!Adatum
End If
arrList(ZeileFuerListbox, 3) = rs!LAgergut
arrList(ZeileFuerListbox, 4) = rs!Anzahl
arrList(ZeileFuerListbox, 5) = rs!Platzbedarf
arrList(ZeileFuerListbox, 6) = rs!Gewicht
If Not IsNull(rs.Fields("Bemerkungen")) Then
arrList(ZeileFuerListbox, 7) = rs!Bemerkungen
End If
arrList(ZeileFuerListbox, 8) = rs!Kundenobjekt
arrList(ZeileFuerListbox, 9) = rs.Fields("Bereich/Team")
arrList(ZeileFuerListbox, 10) = rs!Auftraggeber
arrList(ZeileFuerListbox, 11) = rs!EUser
arrList(ZeileFuerListbox, 12) = rs!Transportfirma
If Not IsNull(rs.Fields("AUser")) Then
arrList(ZeileFuerListbox, 13) = rs!Auser
End If
ZeileFuerListbox = ZeileFuerListbox + 1
rs.MoveNext
Loop
Me.lst_RawDaten.List = arrList

Set rs = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

Venom · 21. Oktober 2010

Hi
danke nochmal

Er meckert jetzt die
Code:

Dim arrList(0 To 13, 0 To rs.RecordCount - 1) As String
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

an mit der Begründung das es einen Konstanten Wert benötigen würde

EarlFred · 21. Oktober 2010

Hallo Venom,

autsch, stimmt.

Code:

ReDim arrList(0 To rs.RecordCount - 1, 0 To 13) As String
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

Venom · 21. Oktober 2010

Habe es wie folgt ergänzt ...
es geht aber ist es richtig:

Code:

Dim arrList() As String
ReDim Preserve arrList(rs.RecordCount, rs.Fields.Count)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

EarlFred · 21. Oktober 2010

Hallo Venom,

da ein Datenfeld standardmäßig nullbasiert ist, erhältst Du damit vermutlich 1 Feld mehr als benötigt. Die "-1" würde dies eliminieren.

[Edit]
Setz mal einen Breakpoint (F9) in die Zeile
Me.lst_RawDaten.List = arrList
Schau Dir dann die Variable arrList im Lokalfesnter an - es müssten alle Daten enthalten sein. Bei Deiner Variante müsste die letzte Zeile bzw. letzte Spalte leer sein.
[/Edit]

Grüße
EarlFred

Venom · 21. Oktober 2010

Ah ok
Code:

ReDim Preserve arrList(rs.RecordCount - 1, rs.Fields.Count)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Merci EarlFred

Schönes Wochenende

EarlFred · 21. Oktober 2010

Hallo Venom,

gerne. Grüß mir die Nochthessenmedrobole!

Auch Dir ein schönes Wochenende
EarlFred

Venom · 22. Oktober 2010

Hallo EarlFred

Habe gerade noch mal was anderes Probiert.
Er sagt jetzt immer "Kein aktueller Datensatz"

Kannst du bitte noch mal drüber schauen oder wer anders natürlkich auch gern :-)

Code:

ReDim MeinStringArray(rs.RecordCount - 1, rs.Fields.Count)

Do While Not rs.EOF
For Counter = 0 To rs.Fields.Count - 1
If Not IsNull(rs.Fields(Counter).Name) Then
MeinStringArray(ZeileFuerListbox, Counter) = rs.Fields(Counter)
End If
ZeileFuerListbox = ZeileFuerListbox + 1
rs.MoveNext
Next Counter
Loop
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

EarlFred · 22. Oktober 2010

Hallo Venom,

die beiden Zeilen
ZeileFuerListbox = ZeileFuerListbox + 1
rs.MoveNext

müssten m. E. nach Next Counter stehen.

Grüße
EarlFred

Venom · 22. Oktober 2010

OH lol
scheiße ;-(((

Danke dafür

EDIT:
Jetzt kommt die Meldung "Unzulässige VErwendung" von NULL

hmmm ich glaub ich lass es bei derersten Variante

Venom · 22. Oktober 2010

Erledigt danke

Code:

Do While Not rs.EOF
For Counter = 0 To rs.Fields.Count - 1
If Not IsNull(rs.Fields(Counter)) Then
MeinStringArray(ZeileFuerListbox, Counter) = rs.Fields(Counter)
End If
Next Counter
ZeileFuerListbox = ZeileFuerListbox + 1
rs.MoveNext
Loop
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Office: Mehrspaltige Listbox füllen

Mehrspaltige Listbox füllen

Mehrspaltige Listbox füllen

Mehrspaltige Listbox füllen

Mehrspaltige Listbox füllen

Mehrspaltige Listbox füllen

Mehrspaltige Listbox füllen - Similar Threads - Mehrspaltige Listbox füllen

[Diagramme] 2 mehrspaltige Tabellen im Vergleich

ListBox mit AddItem aus mehrspaltiger Tabelle befüllen

Mehrspaltige Listbox text zentrieren

Mehrspaltige Listbox Sortieren

ListBox mit mehrspaltiger Tabelle bestücken und einzelne Zeilen löschen

Auswahl mehrspaltiger Listbox in String schreiben/auslesen

Mehrspaltige Listbox Ausgabe verändert Werte