Office: Richtiges Event beim öffnen einer Excel-Datei

Hallo zusammen,

ich habe ein vermeintlich kleines Problem, bei dem ich allerdings bereits seit ein paar Stunden rum probiere:

Ich starte eine Excel-Datei aus einem Formular aus Access heraus, gleichzeitig besitzt die Excel-Datei in einem seperaten Sheet Abfragen mithilfe von MS Query auf die Access Datenbank. Ich benötige ein Event das immer eintritt, allerdings erst nachdem Abfragen gelaufen sind. Bei Workbook_Open wird der Code zu früh ausgeführt, gleiches gilt für Workbook_Activate. Worksheet_Activate funktioniert zwar, allerdings muss immer zuerst zwischen den Sheets gewechselt werden damit das Event eintritt.

Gibt es ein solches Event oder kennt ihr eine andere Lösungsmöglichkeit? Ich habe bereits versucht über Workbook_open eine UserForm zu starten und mit dem Klick auf den Button den Code ausführen zu lassen - aber auch hier tritt der Code vor der Hintergrundabfrage ein.

Ich hoffe ihr versteht was ich meine, falls Fragen vorhanden sein sollten werde ich diese gerne beantworten!


Vielen Dank im Voraus


Edit: Ergänzend um den Sinn dahinter zu verstehen, der Code bezieht sich auf die Daten der Abfragen wird dieser vor den Abfragen ausgeführt enthält das Excel-Sheet auf dem der Fokus liegt falsche/alte Daten

:)

 

Hallo,

du kannst das Event AfterRefresh auswerten.

 

Hi, danke für deine Antwort,

wie genau meinst du auswerten?
Das Event finde ich weder bei Workbook noch bei Worksheet

 

Hallo,

das ist ja auch ein Event der QueryTable-Klasse. Du musst also nur so eine Klasse anlegen und im Open-Event der Mappe initialisieren. Dann kannst du das AfterRefresh-Event abfangen und damit einfach in der Tabelle ein weiteres Event mit deinem Makro triggern.

Kriegst du das hin oder brauchst du ein Beispiel?

 

Hallo,

ein Beispiel wäre nicht schlecht falls du dir die Zeit nehmen kannst, ansonsten werde ich versuchen mich mit Google durchzuschlagen

 

Hallo,

im Modul "DieseArbeitsmappe" (Tabellen-Objekt-Name anpassen):

Option Explicit

Private Sub Workbook_BeforeClose(Cancel As Boolean)
If Not Saved Then
Select Case MsgBox("Sollen Ihre Änderungen in '" & Name & _
"' gespeichert werden", vbExclamation Or vbYesNoCancel)
Case vbYes
Save
Case vbNo
Saved = True
Case vbCancel
Cancel = True
End Select
End If
If Not Cancel Then Call Tabelle1.Terminate_Class
End Sub

Private Sub Workbook_Open()
Call Tabelle1.Init_Class
End Sub

Im Modul der Tabelle:

Option Explicit

Private WithEvents mobjQueryTable As clsQueryTable

Friend Sub Init_Class()
Set mobjQueryTable = New clsQueryTable
Set mobjQueryTable.prpQueryTable = QueryTables(1)
End Sub

Friend Sub Terminate_Class()
Set mobjQueryTable = Nothing
End Sub

Private Sub mobjQueryTable_Refresh(ByVal pvblnRefresh As Boolean)
If pvblnRefresh Then

'Hier kommt dein Code

End If
End Sub

In einem Klassenmodul mit dem Namen "clsQueryTable":

Option Explicit

Private WithEvents mobjQueryTable As QueryTable

Public Event Refresh(ByVal pvblnRefresh As Boolean)

Private Sub Class_Terminate()
Set mobjQueryTable = Nothing
End Sub

Friend Property Set prpQueryTable(ByRef probjQueryTable As QueryTable)
Set mobjQueryTable = probjQueryTable
End Property

Private Sub mobjQueryTable_AfterRefresh(ByVal Success As Boolean)
RaiseEvent Refresh(True)
End Sub

Private Sub mobjQueryTable_BeforeRefresh(Cancel As Boolean)
RaiseEvent Refresh(False)
End Sub

 

Wow, vielen Dank für deine Bemühungen!

Habe alles 1:1 so übernommen, als ich den Namen von Tabelle1 angepasst habe, habe ich Fehlermeldungen bekommen... die sind jetzt aber wie gesagt beseitigt, allerdigns gibt

Code:

"Index außerhalb des gültigen Bereiches"

Würde mich gerne selbst an die Fehlerbehebung machen, meine VBA kenntnisse reichen dafür aber kaum aus. Hast du eine Idee was falsch ist?

 

Hallo,

der Code muss in das Modul der Tabelle in der die Daten gezogen werden,

 

Hi,

mein Fehler, habe ich geändert, bekomme keine Fehlermeldung mehr, allerdings tut sich auch nichts, sprich der Code wird nicht angesprochen.

Hast du noch eine Idee?

 

Hallo,

ohne die Mappe zu kennen schwer zu sagen an was es liegt. Wahrscheinlich ist aber dass dein Query schon läuft bevor der Code greifen kann. Ich würde mal versuchen den automatischen Refresh raus zu nehmen und diesen im Open-Event per VBA anzusteuern.