Office: (Office 2003) Serienbrief aus Access heraus starten (Lösung)

Gregor0310 · 29. November 2010

Hallo Leute,

Lasse jetzt gemäß Eberhards Vorschlag jedesmal eine Excel-Tabelle generieren. Es läuft so weit ganz gut, allerdings mit der Einschränkung,
dass in einer Mehrbenutzerumgebung (aufgrund der festen Datenquellenadressen in WORD) jeweils nur eine Person zugreifen kann.

Der Serienbrief ist unter WORD 2003 generiert; unter WORD 2000 habe ich
das Problem, dass er die Datenquelle nicht findet (siehe Anlage).
Er bringt mir auch nicht die Symbolleiste der Serienbriefe.
Habt ihr eine Idee dazu?

Beste Grüße
Gregor

ebs17 · 29. November 2010

dass in einer Mehrbenutzerumgebung ... jeweils nur eine Person zugreifen kann
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

In einer Mehrbenutzerumgebung
- hat jeder sein eigenes Frontend?
- arbeiten mehrere gleichzeitig am gleichen Serienbrief? Was mach ihr da?

Hier mal ein vollständiger Code von Anne Berg:
Code:

Option Compare Database
Option Explicit

'============================================================================================
' Hinweis: Verweis auf Word nicht erforderlich !!
'============================================================================================

'--------------------------------------------------------------------------------------------
' Modul: mdl_wordApp
'
' Prozedur: rzf_SBrief
'
' Funktion: Erstellen von Serienbriefen auf Basis von Word-Vorlagen mit
' dynamischer Einbindung einer Excel-Datenquelle
'
' Voraussetzung:
' Die Seriendruckvorlage enthält die benötigten Seriendruckfelder, ist
' aber selbst an keine Datenquelle gebunden!
' (--> nach Erstellen/Ändern der Vorlage Datenquelle entfernen!)
' Parameter:
' docName = Word-Dokument/Vorlage (vollst. Zugriffspfad)
' srcName = Excel-Datenquelle (vollst. Zugriffspfad)
' tabName = Name des Tabellenblatts (=Tabellen-/Abfragename + "$")
' sbType = Anforderungsart
' 1 = Serienbrief über Vorlage mit Datenquelle verbinden
' 2 = SB-Dokument über Vorlage öffnen und Datenquelle einbinden
' 3 = Word-Dokument/Vorlage zur Bearbeitung öffnen u. DQ. einbinden
'
'--------------------------------------------------------------------------------------------

Const wdWindowStateMaximize = 1
Const wdSendToNewDocument = 0
Const wdOpenFormatAuto = 0
Const wdFormLetters = 0
Const wdDoNotSaveChanges = 0
Const wdPageView = 3
Const wdAllowOnlyFormFields = 2
Const wdToggle = 9999998
Const wdPageFitBestFit = 2

Public Sub rzf_SBrief(docName As String, srcName As String, tabName As String, _
Optional sbType As Byte = 1)

Dim conString As String, wdwName As String
Dim Word As Object
Dim docTemplate As String
Dim xlsFileName As String, xlsTabName As String
Dim dbName As String

dbName = CurrentDb.Name()
docTemplate = docName
xlsFileName = srcName
xlsTabName = tabName

' Verbindungs-Parameter
' über ODBC
conString = "DSN=Excel-Dateien;DBQ=" & xlsFileName & ";DriverId=22;MaxBufferSize=2048;PageTimeout=5;"

On Error GoTo Word_Neu
'wenn Word bereits geöffnet ist ...
'Set Word = GetObject(, "Word.Application")
' neue Word-Instanz öffnen - immer!
Set Word = CreateObject("Word.Application")

' Word-Dokument öffnen
Select Case sbType
Case 3
' Öffnen des Dokuments / der Vorlage
Word.Documents.Open fileName:=docTemplate, _
ConfirmConversions:=False, _
ReadOnly:=False, AddToRecentFiles:=False, PasswordDocument:="", _
PasswordTemplate:="", Revert:=False, WritePasswordDocument:="", _
WritePasswordTemplate:="", Format:=wdOpenFormatAuto
Case Else
' Öffnen neues Dokument aus Vorlage
Word.Documents.Add Template:=docTemplate ', _
ConfirmConversions:=False, _
ReadOnly:=False, AddToRecentFiles:=False, PasswordDocument:="", _
PasswordTemplate:="", Revert:=False, WritePasswordDocument:="", _
WritePasswordTemplate:="", Format:=wdOpenFormatAuto
End Select

wdwName = Word.ActiveDocument.Name

' mit Datenquelle verbinden...
Word.ActiveDocument.MailMerge.MainDocumentType = wdFormLetters
Word.ActiveDocument.MailMerge.OpenDataSource Name:=xlsFileName, _
ConfirmConversions:=False, _
ReadOnly:=False, LinkToSource:=True, AddToRecentFiles:=False, _
Connection:=conString, _
SQLStatement:="SELECT * FROM [" & xlsTabName & "]", SQLStatement1:=""
Word.ActiveDocument.MailMerge.ViewMailMergeFieldCodes = wdToggle
Word.ActiveWindow.ActivePane.View.Zoom.PageFit = wdPageFitBestFit

' ... Serienbrief erstellen?
If sbType = 1 Then
With Word.ActiveDocument.MailMerge
.Destination = wdSendToNewDocument ' altern.: wdSendToPrinter
.Execute
End With
Else
End If

With Word
' ... SB-Dokument schließen?
If sbType = 1 Then
.Windows(wdwName).Activate
.ActiveWindow.Close savechanges:=wdDoNotSaveChanges
.ActiveDocument.Protect Password:="", NoReset:=False, Type:=wdAllowOnlyFormFields
.ActiveWindow.ActivePane.View.Zoom.Percentage = 75
End If
.Visible = True
.WindowState = wdWindowStateMaximize
.ActiveWindow.View.Type = wdPageView
.Activate
End With
exit_proc:
Set Word = Nothing
Exit Sub
Word_Neu:
If Err.Number = 429 Then
'wenn Word noch nicht geöffnet ist ...
' ... kommt nicht vor, da immer neue Instanz!
Set Word = CreateObject("Word.Application")
Resume Next
Else
MsgBox Err.Number & " - " & Err.Description, vbCritical, "Serienbriefanforderung"
Resume exit_proc
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gregor0310 · 29. November 2010

Hallo Eberhard,

ich gucke mir mal Anne Bergs Quellcode an.
Im Moment wird mit diesem "Serienbrief" einfach nur eine Rechnung
von verschiedenen Front-Ends aus erstellt.
In der Mehrbenutzerumgebung kann ich den Excel-Tabellen keine verschiedenen Namen geben(z.B. zusätzlich den Front-End-Namen), da ich selbst per VBA für die Seriendruckherkunft eine feste Adresse brauche und
(in WORD) nicht feststellen kann, wer gerade eine Instanz der Dokumentvorlage öffnet. Von ACCESS aus ginge dies, müßte dann aber wieder
in WORD schreiben und kriege wohl meine Fehlermeldung wieder.
Ich muß die alten EXCEL-Dateien löschen, da mein System sich mit einfachen Überschreiben einer bestehenden mit gleichem Namen nicht zufrieden gibt.

Hoffe, es damit ein wenig erklärt zu haben.

Beste Grüße und DANK
Gregor

ebs17 · 29. November 2010

müßte dann aber wieder in WORD schreiben
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bei einem Serienbrief gehe ich davon aus, das der Inhalt vollständig ist und nur variable Inhalte über die Seriendruckfelder zu übergeben sind, und das ist eine Momentsache.

Weiter kann man den erstellten Serienbrief abspeichern. Dieser benötigt dann keine Datenquelle mehr, da alle Inhalte vorhanden sind. Auch kann man dann enthaltene Einzelbriefe individuell nacharbeiten.

zra8886 · 7. Januar 2021

von Gregor0310

...Der Serienbrief ist unter WORD 2003 generiert; unter WORD 2000 habe ich
das Problem, dass er die Datenquelle nicht findet (siehe Anlage).
Er bringt mir auch nicht die Symbolleiste der Serienbriefe.
Habt ihr eine Idee dazu?

Beste Grüße
Gregor
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hallo Gregor,

unter Word 2003 erstellt und Word 2000 solls dann können?
Das funktioniert nicht.

Anders rum wird ein Schuh daraus: Generieren unter Word 2000 und ausführen mit Word 2003 ist möglich.

Und noch eins:

Sehr geehrte(r)

kann man eleganter lösen.

mfg
Roland

Gregor0310 · 19. April 2011

Schönen Guten Morgen,

mal wieder was Neues zu dem Thema.
Meine Serienbriefe greifen (eigentlich *wink.gif* ) jetzt fest auf eine zuvor aus einer Abfrage generierte Excel-Datenquelle zurück. Tja, aber "eigentlich" sagt ja wohl alles.
Leider muß ich nach wie vor, die Datenquelle nach dem Öffnen des Serienbriefes "per Hand" zuweisen.
Nutze WIN XP, OFFICE 2003 und Internet Explorer8; habe im Netz gelesen (---.office-loesung.de Thread: 115560), dass es an den Einstellungen des InternetExplorers für das "Lokale Intranet" liegen könnte???
Aber dies hat auch nicht geholfen?
Lege mal einen Bildschirmausdruck bei. Man beachte die grau hinterlegten Seriendrucksymbolfelder....
Hättet Ihr noch einen Ansatz?

Beste Grüße und Schönes Osterfest
Gregor

Arne Dieckmann · 19. April 2011

OT: Bitte beachte die folgenden 2 Hinweise

Screenshots bitte als png hochladen, nicht in einem doc einbetten!

Falls es sich im Screenshot um eine echte Adresse handelt, ändere den Anhang bitte in den nächsten ~ 2 Stunden.

Gregor0310 · 2. Mai 2011

Hallo Leute,

ist euch das Problem "in derart" bekannt?

Viele Grüße
Gregor

ebs17 · 2. Mai 2011

Ich verstehe vor allem nach wie vor den Ablauf und die Rahmenbedingungen nicht. Die Erstellung eines Briefes (wie auch immer) ist doch eine Momentsache. Es werden ja nicht 10 User gleichzeitig den gleichen Brief mit gleichen Inhalten anlegen wollen. Also kann die Datenquelle für den Seriendruck lokal beim jeweiligen User generiert werden (wie auch immer).
Code:

With oDoc.MailMerge
.OpenDataSource Name:=DummyTxt, LinktoSource:=True
.Execute
End With
With oDoc
.SaveAs FileName:=Zieldatei
If DocClose Then .Close
End With
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hier wird die Seriendruck-Datenquelle (DummyTxt) per VBA zugewiesen (wenn man schon das Dokument per VBA erzeugt). Mit der Execute-Methode werden die Daten fest ins Dokument eingefügt, sprich aus 10 Datensätzen entsteht ein 10-seitiges Dokument.
Das somit entstandene Dokument kann abgespeichert werden, die (bisherige) Datenquelle kann gelöscht oder anderwertig verwendet werden, weil für diesen Serienbrief nicht mehr benötigt.

Gregor0310 · 12. Mai 2011

Hallo Leute,
hallo Ebs,

Vielen Dank für den Tipp soweit.
Bin kurz vor des Rätsels Lösung. Gemäß deiner Empfehlung ist der Code nun wie folgt:
Code:

oDoc.MailMerge.OpenDataSource Name:=DBPfad & "export.xls", LinktoSource:=True, Connection:="Table Table1"
oDoc.MailMerge.Execute
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Kriege aber in der Excel-Mappe noch die Frage nach der Tabelle/Datenquelle.(siehe Anlage) Wie kann ich das denn 'OpenDataSource' sagen, dass es nicht mehr nach der Tabelle fragen soll?

Vielen Dank und ein Schönes Wochenende
Gregor

Gregor0310 · 15. Mai 2011

Up, up and away...*Smilie

Die Antwort auf meine kleine Zusatzfrage weiß doch bestimmt jemand?

Gregor0310 · 19. Mai 2011

Fällt euch etwas zum "OpenDatasource" und der Tabellenname-Weitergabe ein?

Viele Grüße und ein Schönes Wochenende.
Gregor

ebs17 · 19. Mai 2011

Code:

Connection:="Table Table1"
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das muss so heißen?

Im Zweifelsfall würde ich mir eine funktionierende Verknüpfung zu einer Exceltabelle auslesen und diese dann nachstellen.

Office: (Office 2003) Serienbrief aus Access heraus starten (Lösung)

Serienbrief aus Access heraus starten (Lösung)

Serienbrief aus Access heraus starten (Lösung)

Serienbrief aus Access heraus starten (Lösung)

Serienbrief aus Access heraus starten (Lösung)

Serienbrief aus Access heraus starten (Lösung)

Serienbrief aus Access heraus starten (Lösung) - Similar Threads - Serienbrief Access starten

Serienbrief, Datum plus 7 Tage

Über Access VBA ein Worddokument Datenquelle/Serienbrief erstellen

Serienbrief mit Word aus Access-VBA

Serienbrief: Access-Datenbank als Datenquelle - Datumsabfrage WENN-DANN-SONST

Word 365 lässt Datensätze aus Access im Serienbrief "verschwinden"

Wer hat viel Ahnung von Serienbriefe?

Namensschildchen aus Access als Serienbrief