Office: Sverweis soll Spalten addieren

Hallo,

kann man per sverweis auch definieren dass mehrere Spalten die neben dem Suchkriterium stehen addiert werden?

Ich habe das zwar hinbekommen, halte die Lösung aber für eher kompliziert.

=SVERWEIS(A3;'[ACG MB.xls]ACG MB'!$A$10:$BB$190;36;FALSCH)+SVERWEIS(A3;'[ACG MB.xls]ACG MB'!$A$10:$BB$190;37;FALSCH)+SVERWEIS(A3;'[ACG MB.xls]ACG MB'!$A$10:$BB$190;37;FALSCH)

Gibt es auch eine elegantere Lösung?

 

Hallo,

hier würde ein SUMMENPRODUKT() langen, wenn das Suchkriterium nur einmal vorkommen kann.

	A	B	AI	AJ	AK	AL
1	111
2
3
4	ich			37	37	37
5				38	38	38

Zelle	Formel
A1	=SUMMENPRODUKT((A3:A10="ich")*(AJ3:AL10))

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

 

Hallo,

geht auch mit Sverweis:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
15	heinz	24
16	gert		5	6	7	8	9
17	heinz	1	2	4	9	2	6

Zelle	Formel
B15	{=SUMME((SVERWEIS(A15;A16:G17;ZEILE(2:7);0))*1)}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

Gruß

Edgar

 

hi (ladehemmung?, okay!), ich habe auch noch eine variante... ... aber nur der vollständigkeit halber, allen fehlt allerdings eine fehlerabfrage... ... die kriegt man aber auch alleine hin, gelle?

Arbeitsblatt mit dem Namen 'Tabelle4'
	A
3	20
4	231
5	231
6	231
7	231

Zelle	Formel
A4	=SVERWEIS(A3;'[ACG MB.xlsx]ACG MB'!$A$10:$BB$36;36;0)+SVERWEIS(A3;'[ACG MB.xlsx]ACG MB'!$A$10:$BB$36;37;0)+SVERWEIS(A3;'[ACG MB.xlsx]ACG MB'!$A$10:$BB$36;38;0)
A5	{=SUMME((SVERWEIS(A3;'[ACG MB.xlsx]ACG MB'!$A$10:$BB$36;ZEILE(2:38);0))*1)}
A6	=SUMMENPRODUKT(('[ACG MB.xlsx]ACG MB'!$A$10:$A$36=A3)*('[ACG MB.xlsx]ACG MB'!$AJ$10:$AL$36))
A7	=SUMME(INDEX('[ACG MB.xlsx]ACG MB'!$AJ$10:$AL$36;VERGLEICH(A3;'[ACG MB.xlsx]ACG MB'!$A$10:$A$36;0);))

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

 

Hallo!

Damit dürften wir (also IHR) alle sinnvollen Varianten durch haben und das Problem sollte mehr als gelöst sein.
Was ist aber mit dem einfachen SUMMEWENN?
Ich habe es jetzt nicht ausprobiert, ob SUMMEWENN auch geschlossene Dateien wirkt; tut es?

 

hi Schatzi, da ich bekomme #WERT! und bei geöffneter datei ein falsches ergebnis... meine formel war...:

{edited} ich frage mich nur warum der/die frager/in zweimal den spaltenindex 37 gewählt hatte - zufall..? {edited}

=SUMMEWENN('[ACG MB.xlsx]ACG MB'!$A$10:$A$36;A3;'[ACG MB.xlsx]ACG MB'!$AJ$10:$AL$36)

 

Hallo!

Nein, Tippfehler! Das passiert uns allen mal...

 

Edgars Lösung klappt super.
Vielen Dank.
Wenn ich jetzt aber #NV durch 0 ersetzen will, dann will er den Spaltenindex, der vorher geklappt hat nicht mehr haben.

=Wenn(Istfehler(SUMME((SVERWEIS(A3; 'M:\AUTO AGP\[ACG MB.xls.xlsx]ACG MB'!;zeile($36:$40;0))*1));"0"; SUMME((SVERWEIS(A3; 'M:\AUTO AGP\[ACG MB.xls.xlsx]ACG MB'!;zeile($36:$40);0))*1)))

Woran kann das liegen?

 

Hallo!

Da fehlt eine Klammer!

=Wenn(Istfehler(SUMME((SVERWEIS(A3; 'M:\AUTO AGP\[ACG MB.xls.xlsx]ACG MB'!;zeile($36:$40);0))*1));"0"; SUMME((SVERWEIS(A3; 'M:\AUTO AGP\[ACG MB.xls.xlsx]ACG MB'!;zeile($36:$40);0))*1)))

 

Hallo,

Anmerkung:
Quält doch das arme XL nicht so!
=Wenn(ISTNV(SUMME((...;0;....

So muss es nicht alle Fehler durcharbeiten! ;-)
Und die Null ist dann auch auswertbarer!

 

Klappt immer noch nicht :-(
Excel sagt wieder dass die Formel einen Fehler enthält und markiert mir dann das Wort "Zeile" in der Formel!

 

Hallo!

Ich seh jetzt gerade:
Wo sind denn die Zellbezüge geblieben???

=Wenn(Istfehler(SUMME((SVERWEIS(A3; 'M:\AUTO AGP\[ACG MB.xls.xlsx]ACG MB'!???;zeile($36:$40);0))*1));"0"; SUMME((SVERWEIS(A3; 'M:\AUTO AGP\[ACG MB.xls.xlsx]ACG MB'!???;zeile($36:$40);0))*1))

 

hehe optimal, vielen Dank.

Jetzt klappt es und ich kann meiner Abteilung mehrere Stunden Arbeit pro Monat ersparen!