Office: Textdatei Zeilenweise auslesen und in Excel einfügen

classicleon · 31. März 2015

Hallo Leute,
Ich bräuchte mal Hilfe zu folgendem Projekt. Ich habe eine sehr komplexe Textdatei woch sich das untere Beispiel bestimmt 1000 mal wiederholt.
Diese Textdatei möchte/muss ich jetzt mittels Script durchsuchen bspw die Server: und Title: in Office Zeilen einfügen.
Sprich das Skript soll nach Server: suchen und den rest der Zeile in eine Excel Tabelle einfügen.

Die Textdatei ist folgenderweise aufgebaut:

ReplicaID: a1233314:00001545
Server: CN=SRV3000/O=gg/C=DE
Pathname: gg\ablage_23.nsf
ConfigOrgaDBColumnNo: 2
ConfigOrderDBColumnNo: 1
ActiveDB: 1
Title: Anklage Database 2
Abstract: Anklage Database 2
Bereich: E
Anforderer: MichalSpeck/OU=AG/O=GG/C=DE
Kunde: ATZ G
Author: CN=MichalSpeck/OU=AG/O=GG/C=DE
$UpdatedBy: CN=MichalSpeck/OU=AG/O=GG/C=DE,CN=SRV3000/O=GG/C=DE
$Revisions: 10.05.2013 16:50:59

Da sich die Datensätze ständig mit unterschiedlichen parametern wiederholen soll das übersichtlich in Excel gepackt sein:

Title .....Server.......evtl weitere parameter
1 ........... 1
2 ............2
3 ............3
4 ............4

Hat da jemand eine Idee wie man sowas verwirklicht??

Besten Dank *Smilie

:)

xlph · 1. April 2015

Hallo,

versuch es hiermit:

Code:

Sub xlph()

Dim strPfad As String
Dim strText As String
Dim astrText() As String
Dim lngT As Long

Dim astrZeile() As String

Dim dic As Object
Dim varKey As Variant

Dim lngS As Long
Dim avarItems As Variant

Set dic = CreateObject("scripting.dictionary")

strPfad = "C:\Test\TTT.txt"

strText = ReadTxtFile(strPfad)

astrText() = Split(strText, vbNewLine)

' Splitten und sammeln
For lngT = LBound(astrText) To UBound(astrText)
If InStr(astrText(lngT), ":") > 0 Then
astrZeile() = Split(astrText(lngT), ":", 2)
dic(astrZeile(0)) = dic(astrZeile(0)) & vbLf & Trim$(astrZeile(1))
End If
Next

' Spaltenweise ausgeben
For Each varKey In dic.Keys
lngS = lngS + 1

avarItems = Split(Mid$(dic(varKey), 2), vbLf)

Cells(1, lngS).Value = varKey
Cells(2, lngS).Resize(UBound(avarItems) + 1).Value = _
WorksheetFunction.Transpose(avarItems)
Next

End Sub

Function ReadTxtFile(ByVal Path As String) As String
Dim intFF As Long

' Falls ohne Inhalt, abbrechen
On Error Resume Next
If FileLen(Path) = 0 Then Exit Function
On Error GoTo 0

' Datei lesen
intFF = FreeFile()
Open Path For Binary As #intFF
ReadTxtFile = Space$(LOF(intFF))
Get #intFF, , ReadTxtFile
Close #intFF
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

haklesoft · 1. April 2015

oder hiermit: Code:

Sub Textfelder()
On Error GoTo TextfelderErr
Dim vDatei As Variant
Dim kn As Integer
Dim sZeile As String
Dim sDaten() As String
Dim lRow As Long, lCol As Long

lRow = 1
lCol = 1

Cells(lRow, 1).Value = "Server"
Cells(lRow, 2).Value = "Title"
Cells(lRow, 3).Value = "Kunde"
'ggf. weitere in Datenreihenfolge

vDatei = Application.GetOpenFilename("Text Files (*.txt), *.txt")
If vDatei False Then
'Debug.Print vDatei
kn = FreeFile
Open vDatei For Input As #kn
Do While Not EOF(kn)
Line Input #kn, sZeile
'Debug.Print sZeile
sDaten = Split(sZeile, ":")
If UBound(sDaten()) > 0 Then
Select Case sDaten(0)
Case "Server"
lRow = lRow + 1
lCol = 1
Cells(lRow, lCol).Value = sDaten(1)
Case "Title", "Kunde" 'ggf. weitere in Datenreihenfolge
lCol = lCol + 1
Cells(lRow, lCol).Value = Trim$(sDaten(1))
End Select
End If
Loop
Close #kn
End If
Exit Sub

TextfelderErr:
If MsgBox(Err.Description & vbCrLf & vbCrLf & "Trotzdem weiter machen?", vbYesNo + vbQuestion, "Fehler Nr. " & Err.Number) = vbYes Then
Resume Next
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

classicleon · 1. April 2015

Besten Dank...

Funktioniert SUPER

Office: Textdatei Zeilenweise auslesen und in Excel einfügen

Textdatei Zeilenweise auslesen und in Excel einfügen

Textdatei Zeilenweise auslesen und in Excel einfügen

Textdatei Zeilenweise auslesen und in Excel einfügen

Textdatei Zeilenweise auslesen und in Excel einfügen - Similar Threads - Textdatei Zeilenweise auslesen

Große Textdatei - Formate entschlacken

textdatei auslesen

Export als Textdatei in UTF-8

Textdatei mit Semikolon getrennten Werten in Verteilerliste in Outlook exportieren

Textdatei zeilenweise zum Auswerten einlesen

Textdatei Zeilenweise einlesen: Zeilenumbruch wird nicht erkannt

Textdatei zeilenweise einlesen