Office: Texte aus einer Zelle auslesen.

Hallo Guten Morgen,

ich habe ein Problem mit einer Exceltabelle.

Dort muss ich aus einem Text einzelne Teile auslesen.
MONAXIS 83-R.375 C3 DL oder MONAXIS 80-NCH.250 C2 L
oder IRIOS -GS.CE183 C8 e*cube.

Als erstes lese ich alles vor dem ersten Leerzeichen aus das klappt ganz gut und zwar mit =LINKS(A2;SUCHEN(" ";A2;1)-1) also im ersten Fall Monaxis im zweiten auch in dritten Irios, dieses lege ich in einer eingenen Spalte ab. als nächstes benötige ich den Wert hinter dem Punkt (375 oder 250 oder CE183) der soll auch in einer separaten Spalte abgelegt werden. Dann möchte ich noch wenn vorhanden den Text NC wenn vorhanden in eine eigene Spalte, das gleiche gilt auch für den Text e*cube.

Wer kann weiter helfen?

Rcorner

 

Hi,

meinst du das so:

Tabelle1

	A	B	C	D	E
2	MONAXIS 83-R.375 C3 DL	MONAXIS	375
3	MONAXIS 80-NCH.250 C2 L	MONAXIS	250	NC
4	IRIOS -GS.CE183 C8 e*cube	IRIOS	CE183		e*cube

verwendete Formeln
Zelle	Formel
B2	=LINKS(A2;SUCHEN(" ";A2;1)-1)
C2	=LINKS(RECHTS(A2;LÄNGE(A2)-FINDEN(".";A2));FINDEN(" ";RECHTS(A2;LÄNGE(A2)-FINDEN(".";A2));1)-1)
D2	=WENN(LÄNGE(A2)-LÄNGE(WECHSELN(A2;"NC";""))=0;"";"NC")
E2	=WENN(LÄNGE(A2)-LÄNGE(WECHSELN(A2;"e*cube";""))=0;"";"e*cube")
B3	=LINKS(A3;SUCHEN(" ";A3;1)-1)
C3	=LINKS(RECHTS(A3;LÄNGE(A3)-FINDEN(".";A3));FINDEN(" ";RECHTS(A3;LÄNGE(A3)-FINDEN(".";A3));1)-1)
D3	=WENN(LÄNGE(A3)-LÄNGE(WECHSELN(A3;"NC";""))=0;"";"NC")
E3	=WENN(LÄNGE(A3)-LÄNGE(WECHSELN(A3;"e*cube";""))=0;"";"e*cube")
B4	=LINKS(A4;SUCHEN(" ";A4;1)-1)
C4	=LINKS(RECHTS(A4;LÄNGE(A4)-FINDEN(".";A4));FINDEN(" ";RECHTS(A4;LÄNGE(A4)-FINDEN(".";A4));1)-1)
D4	=WENN(LÄNGE(A4)-LÄNGE(WECHSELN(A4;"NC";""))=0;"";"NC")
E4	=WENN(LÄNGE(A4)-LÄNGE(WECHSELN(A4;"e*cube";""))=0;"";"e*cube")

http://c.excelhost.de/c_beverly/getfile.php?id=122 Tabellendarstellung in Foren Version 5.3


Hinweis: bitte ignorieren, die Forumssoftware setzt XHTML-Code falsch um.

Bis später,
Karin

 

Tausend Dank

Hallo,

vielen Dank ist eine ganze Tolle Hilfe. Hätte ich so nicht hin bekommen.
Arbeit von Stunden in Sekunden.

LG

Rcorner