Office: VBA -Code für Schriftfarbe je nach Inhalt ändern

Hallo zusammen,

ich habe folgendes Problem:

Ich möchte über einen VBA-Code die Schriftfarbe einer Zelle(B3) von rot zu grün ändern, wenn sich in (D3) ein "-"Zeichen befindet. (Bedingte Formatierung kann nicht verwendet werden).

Wie schaffe ich es, dass der Code immer und sofort angewendet wird nicht erst nach betätigen eines Buttons oder so?

Danke für eure Hilfe
Liquid

:)

 

benutze das Ereignis
Private Sub Worksheet_Change(ByVal Target As Range)
Mit VBA kennst Du Dich ja Klasse aus, da bedingte Formatierung gestrichen.

 

Hi,

z.B. so:

Code:

 

Hallo Liquid,

Rechtsklick auf den Tabellenreiter - Code anzeigen. Folgende Prozedur in das sich öffnende Codefenster kopieren:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim objRange As Range, objCell As Range
Set objRange = Intersect(Target, Columns(4))
If Not objRange Is Nothing Then
For Each objCell In objRange
With objCell
If .Value = "-" Then
.Offset(0, -2).Font.Color = vbRed
Else
.Offset(0, -2).Font.Color = vbGreen
End If
End With
Next
Set objRange = Nothing
End If
End Sub

Dann mit der Tastenkombination Alt+q den VBA-Editor schließen. Anschließend die vorhandenen Einträge in Spalte D mit F2 - Enter durchgehen und staunen.

 

Danke Nepumuk,

für deinen Code und die Erläuterungen (es ist schön, wenn die Wissenden ihre Machtposition nicht ausnutzen, um die Unwissenden nieder machen, nur weil sie Hilfe brauchen.)

Ich habe den Code eingebaut und gestaunt, als es funktioniert hat. Nur ist es im Moment so, dass alle Felder rot werden. Die Unterscheidung nach dem "-" = Grün scheint nicht zu funktionieren.

Kann man die Formatierung auch so machen, dass man sagt: "Lass die Formatierung(Farbe,Kursive...) wie sie ist, nur wenn "-" dann mache den Text rot?

-

 

... jetzt geht es !!!

Ich habe " - " zwei Leerzeichen links und rechts hinzufügen müssen.

Cool. Danke.


Noch ein Letztes:

Gibt es statt F2 ENTER je Zelle, noch eine andere Möglichkeit den Code automatisiert auf die Zellen anzuwenden? Ansonsten müsste ich 4500 Mal alles per Hand durchführen !!!

Danke
Liquid
-

 

Hallo Liquid,

du wolltest doch dass es automatisch funktionier und nicht per Knopfdruck. Der Code funktioniert schon automatisch wie du siehst wenn du in eine Zelle F2 + Enter machst reagiert er auf die Änderung in der Zelle auch wenn keine wirkliche Änderung ist.

Um deine vorhandenen Zeilen zu färben brauchst du temporär folgende Prozedur:

Option Explicit

Public Sub Schriftfarbe()
Dim objCell As Range
For Each objCell In Range(Cells(6, 4), Cells(Rows.Count, 4).End(xlUp))
With objCell
If .Value = "-" Then
.Offset(0, -2).Font.Color = vbRed
Else
.Offset(0, -2).Font.Color = vbGreen
End If
End With
Next
End Sub

Dazu mit Alt+F11 den VBA-Editor öffnen und in dessen Menüleiste unter Einfügen - Modul auswählen. In das sich öffnende Codefenster obige Prozedur kopieren. Mit Alt+q den Editor wieder schließen und mit Alt+F8 die Makroliste aufrufen. Dort die Prozedur "Schriftfarbe" mit einem Doppelklick starten.

Nachdem die Prozedur durchgelaufen ist, könntest du sie wieder löschen, denn in Zukunft reagiert ja das erste Makro von mir automatisch auf eine Eingabe.

 

Hey Nepumuk,

alles funktioniert jetzt so wie erhofft.

Viiiiiiiiiiiiiiiiielen Dank.