Office: VBA- Letzte Zeile einer TXT Datei ermitteln

Hallo
ich lese mit folgendem Code eine TXT Datei Zeilenweise ein.

Code:

Sub txt()
    Dim lngZeile&, lngRow&, strFile$, strTxt$, DatIn As Object, i%, j%, wsAP As Worksheet
    Dim strDatum As String, t As Long
     Application.ScreenUpdating = False
    
     strFile = "c:\test\test.txt"
     Set DatIn = CreateObject("Scripting.FileSystemObject").OpenTextFile(strFile, 1, False)
     Set wsAP = ThisWorkbook.Worksheets("AP")
     Do While DatIn.AtEndOfStream <> True
          strTxt = DatIn.ReadLine
          lngRow = lngRow + 1
          wsAP.Cells(lngRow, 1) = strTxt
     Loop
     DatIn.Close
End Sub

Vorher möchte ich aber wissen wieviele Zeilen in der TXT Datei sind. Kann ich mir gleich die Anzahl ausgeben lassen, ohne jede Zeile durchzuzählen?

Ich benutze Excel 2010

Danke

 

Hallo,

falls die Textdatei nicht allzu groß ist, kann man auch folgendermaßen vorgehen, indem man statt der "ReadLine"-Methode des "TextStream"-Objektes die "ReadAll"-Methode anwendet. Dabei wird gleich die ganze Textdatei eingelesen, sodass man den Inhalt einer Stringvariablen (DatZeilen$) zuweisen kann.
Mit Hilfe der "Split"-Funktion kann man über die Zeilenendezeichen (meist CR+LF) die Textzeilen einer dynamisch dimensionierten String-Array-Variablen (Zeilen$) zuweisen und über die UBOUND-Funktion die obere Dimension (=Zeilenanzahl) dieser Variablen ermittlen.

Code:

Sub txt2()
    Dim lngZeile&, lngRow&, strFile$, strTxt$, i%, j%, wsAP As Worksheet
    Dim DatZeilen$, Zeilen$(), ZeilenAnzahl&
    'Dim DatIn As Scripting.TextStream, fs As Scripting.FileSystemObject
    Dim DatIn As Object
    
    Dim strDatum As String, t As Long
    Application.ScreenUpdating = False
    'Set fs = New FileSystemObject
    'Set DatIn = fs.OpenTextFile(strFile, ForReading, False)
    strFile = "c:\test\test.txt"
    Set DatIn = CreateObject("Scripting.FileSystemObject").OpenTextFile(strFile, 1, False)
    Set wsAP = ThisWorkbook.Worksheets("AP")
    DatZeilen$ = DatIn.ReadAll
    DatIn.Close
    
    'falls das Zeilenende der Textdatei aus CR+LF-Zeichen besteht:
    Zeilen$ = Split(DatZeilen$, vbCrLf)
    ZeilenAnzahl& = UBound(Zeilen$)
     
    For lngRow = 0 To ZeilenAnzahl&
      wsAP.Cells(lngRow+1, 1) = Zeilen$(lngRow)
    Next lngRow
    
    Application.ScreenUpdating = True
End Sub

 

Hi Anton,

das Auslesen des Arrays sollte auch ohne Schleife gehen:

Code:

    wsAP.Range("A1").Resize(UBound(Zeilen$) + 1, 1) = Application.Transpose(Zeilen$)

Bis später,
Karin

 

Hallo Karin,

danke für den Hinweis. Es gibt eben immer wieder eine Möglichkeit, an die man nicht gedacht hat.