Office: VBA: PDF aus mehreren Tabellenblättern erzeugen

Hallo,

ich möchte mehrere Tabellenblätter in ein einziges pdf generieren.
Theoretisch sollte dies mit diesem Code gehen:

Code:

Sheets(Array("Tabelle1", "Tabelle2", "Tabelle3")).Select
    
Selection.ExportAsFixedFormat Type:=xlTypePDF, Filename:=ThisWorkbook.Path & "\Mappe.pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True

Probleme in der Praxis
1) Ich weiß vorher nicht, welche Tabellen genau gedruckt werden sollen (wird vorher abgefragt)
--> Wollte ich lösen, indem ich das Array (also die Tabellennamen in der Aufzählung) über Umwege als String generieren lasse - "Index außerhalb des gültigen Bereiches". Hab da auch schon einiges ausprobiert, mal mit Anführungszeichen, mal ohne, mit Leerzeichen, mal ohne...
2) Offenbar werden die Druckbereiche einfach ignoriert. Gedruckt werden nur die in den Tabellenblättern zuletzt markierten Zellen.
--> ist sehr merkwürdig. Nehme ich als Code thisworkbook.sheets("Tabelle1").ExportAsFixedFormat ... klappts. Aber auch bei dieser Variante kann ich immer nur ein Tabellenblatt gleichzeitig auswählen.

Hat irgend jemand eine Idee wie dies elegant zu lösen sein könnte?
Gruß Stefan

 

Hallo Stefan,

das funktioniert, wenn man dynamische String-Arrays verwendet. Im folgenden Codebeispiel anhand deiner Vorgabe habe ich das demonstriert.

das liegt daran, dass du die Methode "ExportAsFixedFormat" auf das Selection-Objekt statt auf das ActiveSheet-Objekt angewendet hast. Der folgende Code enthält die entsprechende Abänderung:

Code:

Sub Makro1()

    'Einen dynamischen String-Array deklarieren:
    Dim arrBlätter() As String
    
    'Diesen Array zB. auf 2 Elemente festlegen:
    ReDim arrBlätter(1 To 2)
    arrBlätter(1) = "Tabelle1"
    arrBlätter(2) = "Tabelle2"
    
    'Falls eine Vergrößerung zB. auf 3 Elemente notwendig ist,
    'ohne dabei die bisherigen Elementinhalte zu verlieren:
    ReDim Preserve arrBlätter(1 To 3)
    
    arrBlätter(3) = "Tabelle3"
    
    Sheets(arrBlätter).Select
    Sheets(arrBlätter(1)).Activate
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
        Filename:=ThisWorkbook.Path & "\Mappe.pdf", _
        Quality:=xlQualityStandard, IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, OpenAfterPublish:=True
        
    'Deselektion der 3 Arbeitsblätter:
    Sheets("Tabelle3").Select
End Sub

 

Hallo Anton,
vielen Dank für Deine Hilfe! So habe ich es jetzt auch hinbekommen!
Gruß Stefan

 

Hallo Anton,
vielen Dank für Deine Hilfe! So habe ich es jetzt auch hinbekommen!
Gruß Stefan