Office: VBA Worksheet_SelectionChange für einen bestimmten Tabellenbereich???

Hallo,
ich will in einem bestimmten Bereich ein Code ausführen, wenn ich in diesem Bereich eine Zelle anklicke. Das habe ich soweit mit diesem Code gelösst:

Code:

Private Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)
  Dim rngBereich As Range, rngZelle As Range, lngAktivZelle As Long
    ActiveSheet.Unprotect
    With Worksheets("MAIN")
    
        Set rngBereich = Range("B2:J10")
        rngBereich.Interior.ColorIndex = 0
        lngAktivZelle = ActiveCell.Value
        
        For Each rngZelle In rngBereich
            If rngZelle.Value = lngAktivZelle And rngZelle.Value <> "" Then rngZelle.Interior.ColorIndex = 36
        Next rngZelle
    End With
    ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
End Sub

Mein Problem ist noch das der Code immer ausgeführt wird, sobald ich in diesem Tabellenblatt irgendwo hin klicke. Der code soll aber nur ausgeführt werden, wenn in dem Bereich B2:J10 geklickt wird. Jemand eine Idee wie man das lösen kann?

Ich benutze Excel 2010

Danke!

 

Hi Marius,

befindet sich der Code im Codemodul des Tabellenblattes "Main", dann brauchst du keinen With-Bezug.

Code:

Private Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)
   Dim rngBereich As Range, rngZelle As Range, lngAktivZelle As Long
   Set rngBereich = Range("B2:J10")
   If Not Intersect(Target, rngBereich) Is Nothing Then
      ActiveSheet.Unprotect
      rngBereich.Interior.ColorIndex = xlNone
      lngAktivZelle = ActiveCell.Value
      For Each rngZelle In rngBereich
         If rngZelle.Value = lngAktivZelle And rngZelle.Value <> "" Then rngZelle.Interior.ColorIndex = 36
      Next rngZelle
      ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
   End If
End Sub

Bis später,
Karin

 

Danke, Perfekt!!!!!!