Office: (Office 2003) Verweise per VBA auslesen, setzen und löschen

Lars M · 12. November 2008

Guten Morgen,

ich suche nach einer Möglichkeit Verweise per VBA auszulesen, zu setzen oder zu löschen.

Kann mir da jemand helfen?

Danke

Lars

:)

Kalle Reiber · 13. November 2008

Hallo,

habe auf die Schnelle den nachfolgenden Code rausgekramt. Er sollte so funktionieren, wie er ist. Ist auch etwas dokumentiert:
Code:

Attribute VB_Name = "mdl_Verweise"
Option Compare Database
Option Explicit

Public Function SetReference(strNameVerweis As String, strPathAndFile As String) As Integer
'-----------------------------------------------------------------------------------------------------------------
' Funktion: Verweise per Code anpassen
'
' Parameter: strNameVerweis - Bezeichnungen des Verweises
' strPathAndFile - Dateiname des Verweises
'
' Rückkehrcode: 0 - i.O.
' 1 - Datei nicht gefunden
'-----------------------------------------------------------------------------------------------------------------
Dim i As Integer

If Dir(strPathAndFile) = "" Then
'referenzierte Datei nicht gefunden
SetReference = 1
Exit Function
Else
'References-Auflistung durchsuchen nach dem übergebenen Verweis
For i = 1 To References.count
If References(i).Name = strNameVerweis Then
'alten (und vielleicht falschen) Verweis löschen
References.Remove References(strNameVerweis)
Exit For
End If
Next i

'Verweis setzen
References.AddFromFile strPathAndFile
End If

End Function

Public Function ListAndCheckReferences()
'-----------------------------------------------------------------------------------------------------------------
'Verweise per Code anpassen
'
'Wenn eine Datenbank regelmäßig abschmiert oder es aus anderen Gründen notwendig ist, öfter die Verweise auf externe
'Bibliotheken zu erneuern, hilft der nachfolgend beschriebend Code weiter. Damit finden Sie nicht nur heraus,
'welche Verweise kaputt sind, sondern können auch alle Verweise auflisten, Verweise hinzufügen und entfernen.

'Beispieldatenbank
'Die nachfolgenden Schritte können mit der Funktion ListReferences im Modul mdlReferences der Beispieldatenbank AccessSQLDotNet.mdb nachvollzogen werden.
'-----------------------------------------------------------------------------------------------------------------

Dim i As Integer

'Die Ausgabe aller vorhandenen Verweise erfolgt mit nachfolgender Prozedur. Sie macht sich die References-Auflistung
'zu Nutze und gibt all ihre Einträge mit Pfad aus.
For i = 1 To Application.References.count
Debug.Print Application.References(i).Name, Application.References(i).FullPath
Next i

'Um die Verweise auf Funktionalität zu prüfen, verwendet man die Eigenschaft IsBroken wie in folgendem Beispiel:
For i = 1 To Application.References.count
Debug.Print Application.References(i).Name, Application.References(i).FullPath, Application.References(i).IsBroken
Next i

'Um vorneweg zu überprüfen, ob es überhaupt kaputte Verweise gibt, kann man folgenden Ausdruck verwenden.
'Er gibt nur den Wert False zurück, wenn alle Verweise in Ordnung sind.
Debug.Print Application.BrokenReference

'Zum Hinzufügen eines Verweises reicht eine Anweisung. Mit der Methode AddFromFile der References-Auflistung fügt man
'einen Verweis auf die nachfolgend angegebene Datei hinzu.

Application.References.AddFromFile "path and filename"

'Zum Entfernen eines Verweises dient die Methode Remove:

Application.References.Remove Application.References("name des verweises")

For i = 1 To Application.References.count
Debug.Print Application.References(i).Name, Application.References(i).FullPath, Application.References(i).IsBroken
Next i

End Function

Public Function CheckReferences() As Variant
'-----------------------------------------------------------------------------------------------------------------
' Funktion : Verweise auf Gültigkeit überprüfen
' Die eingerichteten Verweise der Anwendung werden auf Gültigkeit überprüft.
' Ist ein Verweis ungültig, wird der Name der Datei, auf den der Verweis zeigt,
' in ein Datenfeld aufgenommen. Dieses Datenfeld wird als Funktionsergebnis
' zurückgegeben.
' Parameter: keine
'
' Rückgabe : Datenfeld mit den Dateinamen der fehlerhaften Verweise
' Gibt es keine fehlerhaften Verweise, ist das Feld leer
'-----------------------------------------------------------------------------------------------------------------

Dim i As Integer
Dim Dateinamen() As String

DoCmd.Hourglass True
ReDim Dateinamen(0)
For i = 1 To Application.References.count
If Application.References(i).IsBroken Then
Dateinamen(UBound(Dateinamen)) = Application.References(i).FullPath
ReDim Preserve Dateinamen(UBound(Dateinamen) + 1)
End If
Next i
If UBound(Dateinamen) > 0 Then ReDim Preserve Dateinamen(UBound(Dateinamen) - 1)
CheckReferences = Dateinamen
DoCmd.Hourglass False

Exit Function

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

HZ006 · 13. November 2008

Hallo
ich habe Dein code auch Kopiert und in ein algemeines Modul geladen

bekomme ein Compile Fehler bei
Attribute VB_Name = "mdl_Verweise"

Code 1 zu 1 übernohmen

hast Du auch ein muster aufruf für jede Routine ?

Kalle Reiber · 13. November 2008

Hallo,

die Zeile
Attribute VB_Name = "mdl_Verweise"
kannst du löschen. Sie wird nicht gebraucht (ist durch den Export meines Moduls entstanden)

Hier ein paar Hinweise zum Aufruf der einzelne Funktionen:

Code:

Public Sub TestVerweis()

Const ADO21 = "Microsoft ActiveX Data Objects 2.1 Library" 'Beispiel-Bibliothek

Dim rc As Integer

'-----------------------------------------------------------------------------------------------------------------
' Die Funktion "CheckReferences" prüft die eingerichteten Verweise der Anwendung.
' Ist ein Verweis ungültig, wird der Name der Datei, auf den der Verweis zeigt, in ein Datenfeld aufgenommen.
' Dieses Datenfeld wird als Funktionsergebnis zurückgegeben.
'-----------------------------------------------------------------------------------------------------------------
' Aufruf:
Dim var As Variant
var = CheckReferences()

' Setzen des Verweises, z.B. so:

' Name des Verweises Pfad und Dateiname der Bibliothek
' | |
' | |
' v v
rc = SetReference("Microsoft ActiveX Data Objects 2.1 Library", "C:\Program Files\Common Files\System\ado\msado21.tlb")

'-----------------------------------------------------------------------------------------------------------------
' mit folgender Zeile löscht man einen Verweis

' Name des Verweises
' |
' |
' v
References.Remove References("Microsoft ActiveX Data Objects 2.1 Library")
'-----------------------------------------------------------------------------------------------------------------

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Du mußt natürlich zum Setzen bzw. Löschen eines Verweises den genauen Namen des Verweises kennen.

HZ006 · 14. November 2008

HALLO
Hast Du das schon unter 2007 getestet ?

Kalle Reiber · 14. November 2008

Hallo,

sorry, habe vergessen zu sagen, daß ich unter Windows Vista mit Access 2003 arbeite.
Mit Version 2007 habe ich keine Erfahrung.

Office: (Office 2003) Verweise per VBA auslesen, setzen und löschen

Verweise per VBA auslesen, setzen und löschen

Verweise per VBA auslesen, setzen und löschen

Verweise per VBA auslesen, setzen und löschen

Verweise per VBA auslesen, setzen und löschen - Similar Threads - Verweise VBA auslesen

Werte auslesen mit s(w)verweis

Extras Verweise per VBA setzen

VBA Verweise

VBA-Projekt -> Verweise -> Prüfen ob Vorhanden?

Verweis auf ADO per VBA erstellen

Verweise VBA löschen (Verwaiste)

VBA Lösung Einkauf/Verkauf Erlös